pkgs/by-name/ni/nix-top/package.nix

   1 {
   2   binutils-unwrapped, # strings
   3   coreutils,
   4   getent, # /etc/passwd
   5   fetchFromGitHub,
   6   findutils,
   7   lib,
   8   makeWrapper,
   9   ncurses, # tput
  10   ruby,
  11   stdenv,
  12 }:
  13
  14 # No gems used, so mkDerivation is fine.
  15 let
  16   additionalPath = lib.makeBinPath [
  17     getent
  18     ncurses
  19     binutils-unwrapped
  20     coreutils
  21     findutils
  22   ];
  23 in
  24 stdenv.mkDerivation rec {
  25   pname = "nix-top";
  26   version = "0.3.0";
  27
  28   src = fetchFromGitHub {
  29     owner = "jerith666";
  30     repo = "nix-top";
  31     rev = "v${version}";
  32     hash = "sha256-w/TKzbZmMt4CX2KnLwPvR1ydp5NNlp9nNx78jJvhp54=";
  33   };
  34
  35   nativeBuildInputs = [ makeWrapper ];
  36
  37   buildInputs = [ ruby ];
  38
  39   installPhase =
  40     ''
  41       runHook preInstall
  42       mkdir -p $out/libexec/nix-top
  43       install -D -m755 ./nix-top $out/bin/nix-top
  44       wrapProgram $out/bin/nix-top \
  45         --prefix PATH : "$out/libexec/nix-top:${additionalPath}"
  46     ''
  47     + lib.optionalString stdenv.hostPlatform.isDarwin ''
  48       ln -s /bin/stty $out/libexec/nix-top
  49     ''
  50     + ''
  51       runHook postInstall
  52     '';
  53
  54   meta = {
  55     description = "Tracks what nix is building";
  56     homepage = "https://github.com/jerith666/nix-top";
  57     license = lib.licenses.mit;
  58     maintainers = [ lib.maintainers.jerith666 ];
  59     platforms = lib.platforms.unix;
  60     mainProgram = "nix-top";
  61   };
  62 }