pkgs/by-name/ni/nixos-build-vms/build-vms.nix

   1 {
   2   system ? builtins.currentSystem,
   3   config ? { },
   4   nixpkgs,
   5   networkExpr,
   6 }:
   7
   8 let
   9   nodes = builtins.mapAttrs (vm: module: {
  10     _file = "${networkExpr}@node-${vm}";
  11     imports = [ module ];
  12   }) (import networkExpr);
  13
  14   pkgs = import nixpkgs { inherit system config; };
  15
  16   testing = import "${pkgs.path}/nixos/lib/testing-python.nix" {
  17     inherit system pkgs;
  18   };
  19
  20   interactiveDriver =
  21     (testing.makeTest {
  22       inherit nodes;
  23       name = "network";
  24       testScript = "start_all(); join_all();";
  25     }).test.driverInteractive;
  26 in
  27
  28 pkgs.runCommand "nixos-build-vms" { nativeBuildInputs = [ pkgs.makeWrapper ]; } ''
  29   mkdir -p $out/bin
  30   ln -s ${interactiveDriver}/bin/nixos-test-driver $out/bin/nixos-test-driver
  31   ln -s ${interactiveDriver}/bin/nixos-test-driver $out/bin/nixos-run-vms
  32   wrapProgram $out/bin/nixos-test-driver \
  33     --add-flags "--interactive"
  34   wrapProgram $out/bin/nixos-run-vms \
  35      --set testScript "${pkgs.writeText "start-all" "start_all(); join_all();"}" \
  36      --add-flags "--no-interactive"
  37 ''