pkgs/by-name/og/oggvideotools/package.nix

   1 { lib, stdenv, fetchurl, fetchpatch, cmake, pkg-config, boost, gd, libogg, libtheora, libvorbis }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "oggvideotools";
   5   version = "0.9.1";
   6
   7   src = fetchurl {
   8     url = "mirror://sourceforge/oggvideotools/oggvideotools/oggvideotools-${version}/oggvideotools-${version}.tar.bz2";
   9     sha256 = "sha256-2dv3iXt86phhIgnYC5EnRzyX1u5ssNzPwrOP4+jilSM=";
  10   };
  11
  12   patches = [
  13     # Fix pending upstream inclusion for missing includes:
  14     #  https://sourceforge.net/p/oggvideotools/bugs/12/
  15     (fetchpatch {
  16       name = "gcc-10.patch";
  17       url = "https://sourceforge.net/p/oggvideotools/bugs/12/attachment/fix-compile.patch";
  18       sha256 = "sha256-mJttoC3jCLM3vmPhlyqh+W0ryp2RjJGIBXd6sJfLJA4=";
  19     })
  20
  21     # Fix pending upstream inclusion for build failure on gcc-12:
  22     #  https://sourceforge.net/p/oggvideotools/bugs/13/
  23     (fetchpatch {
  24       name = "gcc-12.patch";
  25       url = "https://sourceforge.net/p/oggvideotools/bugs/13/attachment/fix-gcc-12.patch";
  26       sha256 = "sha256-zuDXe86djWkR8SgYZHkuAJJ7Lf2VYsVRBrlEaODtMKE=";
  27       # svn patch, rely on prefix added by fetchpatch:
  28       extraPrefix = "";
  29     })
  30   ];
  31
  32   postPatch = ''
  33     # Don't disable optimisations
  34     substituteInPlace CMakeLists.txt --replace " -O0 " ""
  35   '';
  36
  37   nativeBuildInputs = [ cmake pkg-config ];
  38
  39   buildInputs = [ boost gd libogg libtheora libvorbis ];
  40
  41   meta = with lib; {
  42     description = "Toolbox for manipulating and creating Ogg video files";
  43     homepage = "http://www.streamnik.de/oggvideotools.html";
  44     license = licenses.gpl2Only;
  45     maintainers = [ ];
  46     # Compilation error on Darwin:
  47     # error: invalid argument '--std=c++0x' not allowed with 'C'
  48     # make[2]: *** [src/libresample/CMakeFiles/resample.dir/build.make:76: src/libresample/CMakeFiles/resample.dir/filterkit.c.o] Error 1
  49     broken = stdenv.hostPlatform.isDarwin;
  50   };
  51 }