pkgs/by-name/om/omnom/package.nix

   1 {
   2   lib,
   3   buildGoModule,
   4   fetchFromGitHub,
   5   makeWrapper,
   6
   7   # for addons
   8   buildNpmPackage,
   9   zip,
  10 }:
  11
  12 buildGoModule rec {
  13   pname = "omnom";
  14   version = "0-unstable-2024-11-20";
  15
  16   src = fetchFromGitHub {
  17     owner = "asciimoo";
  18     repo = "omnom";
  19     rev = "dbf40c9c50b74335286faea7c5070bba11dced83";
  20     hash = "sha256-dl0jfFwn+Fd8/aQNhXFNEoDIMgMia2MHZntp0EKhimg=";
  21     fetchSubmodules = true;
  22   };
  23
  24   vendorHash = "sha256-dsS5w8JXIwkneWScOFzLSDiXq+clgK+RdYiMw0+FnvY=";
  25
  26   patches = [ ./0001-fix-minimal-go-version.patch ];
  27
  28   nativeBuildInputs = [ makeWrapper ];
  29
  30   ldflags = [
  31     "-s"
  32     "-w"
  33   ];
  34
  35   postBuild =
  36     let
  37       omnom-addons = buildNpmPackage {
  38         pname = "omnom-addons";
  39         inherit version src;
  40
  41         npmDepsHash = "sha256-sUn5IvcHWJ/yaqeGz9SGvGx9HHAlrcnS0lJxIxUVS6M=";
  42         sourceRoot = "${src.name}/ext";
  43         npmPackFlags = [ "--ignore-scripts" ];
  44
  45         nativeBuildInputs = [ zip ];
  46
  47         postBuild = ''
  48           mkdir -p $out
  49
  50           zip -r "$out/omnom_ext_src.zip" README.md src utils package* webpack.config.js
  51
  52           pushd build
  53             zip "$out/omnom_ext_chrome.zip" ./* icons/* -x manifest_ff.json
  54             zip "$out/omnom_ext_firefox.zip" ./* icons/* -x manifest_ff.json
  55           popd
  56         '';
  57
  58         postCheck = ''
  59           npm run build-test
  60         '';
  61       };
  62     in
  63     ''
  64       mkdir -p $out/share/addons
  65
  66       # Copy Firefox and Chrome addons
  67       cp -r ${omnom-addons}/*.zip $out/share/addons
  68     '';
  69
  70   postInstall = ''
  71     mkdir -p $out/share/examples
  72
  73     cp -r static templates $out/share
  74     cp config.yml_sample $out/share/examples/config.yml
  75   '';
  76
  77   meta = {
  78     description = "A webpage bookmarking and snapshotting service";
  79     homepage = "https://github.com/asciimoo/omnom";
  80     license = lib.licenses.agpl3Only;
  81     maintainers = lib.teams.ngi.members;
  82     mainProgram = "omnom";
  83   };
  84 }