pkgs/by-name/on/onedrive/package.nix

   1 {
   2   lib,
   3   autoreconfHook,
   4   coreutils,
   5   curl,
   6   fetchFromGitHub,
   7   fetchpatch,
   8   installShellFiles,
   9   ldc,
  10   libnotify,
  11   pkg-config,
  12   sqlite,
  13   stdenv,
  14   systemd,
  15   testers,
  16   # Boolean flags
  17   withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
  18 }:
  19
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "onedrive";
  22   version = "2.5.3";
  23
  24   src = fetchFromGitHub {
  25     owner = "abraunegg";
  26     repo = "onedrive";
  27     rev = "v${finalAttrs.version}";
  28     hash = "sha256-Lek1tW0alQQvlOHpz//M/y4iJY3PWRkcmXGLwjCLozk=";
  29   };
  30
  31   patches = [
  32     # remove when updating to v2.5.4
  33     (fetchpatch {
  34       name = "fix-openssl-version-check-error.patch";
  35       url = "https://github.com/abraunegg/onedrive/commit/d956318b184dc119d65d7a230154df4097171a6d.patch";
  36       hash = "sha256-LGmKqYgFpG4MPFrHXqvlDp7Cxe3cEGYeXXH9pCXtGkU=";
  37     })
  38   ];
  39
  40   outputs = [
  41     "out"
  42     "doc"
  43     "man"
  44   ];
  45
  46   nativeBuildInputs = [
  47     autoreconfHook
  48     installShellFiles
  49     ldc
  50     pkg-config
  51   ];
  52
  53   buildInputs = [
  54     curl
  55     libnotify
  56     sqlite
  57   ] ++ lib.optionals withSystemd [ systemd ];
  58
  59   configureFlags = [
  60     (lib.enableFeature true "notifications")
  61     (lib.withFeatureAs withSystemd "systemdsystemunitdir" "${placeholder "out"}/lib/systemd/system")
  62     (lib.withFeatureAs withSystemd "systemduserunitdir" "${placeholder "out"}/lib/systemd/user")
  63   ];
  64
  65   # we could also pass --enable-completions to configure but we would then have to
  66   # figure out the paths manually and pass those along.
  67   postInstall = ''
  68     installShellCompletion --bash --name onedrive contrib/completions/complete.bash
  69     installShellCompletion --fish --name onedrive contrib/completions/complete.fish
  70     installShellCompletion --zsh --name _onedrive contrib/completions/complete.zsh
  71
  72     substituteInPlace $out/lib/systemd/user/onedrive.service --replace-fail "/usr/bin/sleep" "${coreutils}/bin/sleep"
  73     substituteInPlace $out/lib/systemd/system/onedrive@.service --replace-fail "/usr/bin/sleep" "${coreutils}/bin/sleep"
  74   '';
  75
  76   passthru = {
  77     tests.version = testers.testVersion {
  78       package = finalAttrs.finalPackage;
  79       version = "v${finalAttrs.version}";
  80     };
  81   };
  82
  83   meta = {
  84     homepage = "https://github.com/abraunegg/onedrive";
  85     description = "Complete tool to interact with OneDrive on Linux";
  86     license = lib.licenses.gpl3Only;
  87     mainProgram = "onedrive";
  88     maintainers = with lib.maintainers; [
  89       AndersonTorres
  90       peterhoeg
  91       bertof
  92     ];
  93     platforms = lib.platforms.linux;
  94   };
  95 })