pkgs/by-name/op/openswitcher/package.nix

   1 {
   2   lib,
   3   python3Packages,
   4   fetchFromSourcehut,
   5   desktop-file-utils,
   6   gobject-introspection,
   7   gtk3,
   8   libhandy,
   9   meson,
  10   ninja,
  11   pkg-config,
  12   scdoc,
  13   wrapGAppsHook3,
  14 }:
  15
  16 python3Packages.buildPythonApplication rec {
  17   pname = "openswitcher";
  18   version = "0.11.0";
  19   format = "other";
  20
  21   src = fetchFromSourcehut {
  22     owner = "~martijnbraam";
  23     repo = "pyatem";
  24     rev = version;
  25     hash = "sha256-VBuOnUVB6n8ahVtunubgao9jHPu9ncX0dhDT0PdSFhU=";
  26   };
  27
  28   outputs = [
  29     "out"
  30     "man"
  31   ];
  32
  33   depsBuildBuild = [
  34     pkg-config
  35   ];
  36
  37   nativeBuildInputs = [
  38     desktop-file-utils
  39     gobject-introspection
  40     gtk3
  41     meson
  42     ninja
  43     pkg-config
  44     scdoc
  45     wrapGAppsHook3
  46   ];
  47
  48   dontWrapGApps = true;
  49
  50   buildInputs = [
  51     gtk3
  52     libhandy
  53   ];
  54
  55   propagatedBuildInputs = with python3Packages; [
  56     # for switcher-control, bmd-setup
  57     paho-mqtt
  58     pyatem
  59     pygobject3
  60     # for atemswitch
  61     requests
  62     # for openswitcher-proxy
  63     toml
  64   ];
  65
  66   postInstall = ''
  67     install -Dm644 -t $out/lib/udev/rules.d/ $src/100-blackmagicdesign.rules
  68   '';
  69
  70   preFixup = ''
  71     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  72   '';
  73
  74   meta = with lib; {
  75     description = "Blackmagic Design mixer control application";
  76     downloadPage = "https://git.sr.ht/~martijnbraam/pyatem";
  77     homepage = "https://openswitcher.org/";
  78     license = licenses.gpl3Only;
  79     maintainers = with maintainers; [ hexa ];
  80   };
  81 }