pkgs/by-name/op/openttd-ttf/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   python3,
   6 }:
   7
   8 stdenvNoCC.mkDerivation (finalAttrs: {
   9   pname = "openttd-ttf";
  10   version = "0.6";
  11
  12   src = fetchFromGitHub {
  13     owner = "zephyris";
  14     repo = "openttd-ttf";
  15     tag = finalAttrs.version;
  16     hash = "sha256-Nr3oLiCEdpUhB/IczCEoLM8kb1hGDH/d6WYWRbjgOi8=";
  17   };
  18
  19   nativeBuildInputs = [
  20     (python3.withPackages (
  21       pp: with pp; [
  22         fontforge
  23         pillow
  24         setuptools
  25       ]
  26     ))
  27   ];
  28
  29   postPatch = ''
  30     chmod a+x build.sh
  31     # Test requires openttd source and an additional python module, doesn't seem worth it
  32     substituteInPlace build.sh \
  33       --replace-fail "python3 checkOpenTTDStrings.py ../openttd/src/lang" ""
  34     patchShebangs --build build.sh
  35   '';
  36
  37   buildPhase = ''
  38     runHook preBuild
  39     ./build.sh
  40     runHook postBuild
  41   '';
  42
  43   installPhase = ''
  44     runHook preInstall
  45     install -m444 -Dt $out/share/fonts/truetype */*.ttf
  46     runHook postInstall
  47   '';
  48
  49   meta = with lib; {
  50     homepage = "https://github.com/zephyris/openttd-ttf";
  51     changelog = "https://github.com/zephyris/openttd-ttf/releases/tag/${finalAttrs.version}";
  52     description = "TrueType typefaces for text in a pixel art style, designed for use in OpenTTD";
  53     license = [ licenses.gpl2 ];
  54     platforms = platforms.all;
  55     maintainers = [ maintainers.sfrijters ];
  56   };
  57 })