pkgs/by-name/op/openvas-smb/package.nix

   1 {
   2   fetchFromGitHub,
   3   fetchurl,
   4   lib,
   5   stdenv,
   6   cmake,
   7   git,
   8   pkg-config,
   9   glib,
  10   gnutls,
  11   perl,
  12   heimdal,
  13   popt,
  14   libunistring,
  15 }:
  16 let
  17   heimdalConfigHeader = fetchurl {
  18     url = "https://raw.githubusercontent.com/heimdal/heimdal/d8c10e68a61f10c8fca62b227a0766d294bda4a0/include/heim_threads.h";
  19     hash = "sha256-HEZAyUyjWs0N4bRLbW3tHDHCiTBtdCbgY23JsiYsZCA=";
  20   };
  21 in
  22 stdenv.mkDerivation rec {
  23   pname = "openvas-smb";
  24   version = "22.5.6";
  25
  26   src = fetchFromGitHub {
  27     owner = "greenbone";
  28     repo = "openvas-smb";
  29     tag = "v${version}";
  30     hash = "sha256-wnlBOHYOTWNbwzoHCpsXbuhp0uH3wBH6+Oo4Y+zSsfg=";
  31   };
  32
  33   nativeBuildInputs = [
  34     cmake
  35     git
  36     pkg-config
  37   ];
  38
  39   buildInputs = [
  40     glib
  41     gnutls
  42     perl
  43     heimdal
  44     popt
  45     libunistring
  46   ];
  47
  48   # The pkg expects the heimdal headers to be in a "heimdal" folder, which is the case on
  49   # debian, but not on nix. Additionally some heimdal header names have the same names
  50   # as kerberos header names, so the old include path is removed.
  51   preConfigure = ''
  52     mkdir -p include
  53
  54     # symlink to change include path for heimdal headers from "heim_etc.h" to "heimdal/heim_etc.h"
  55     ln -s ${heimdal.dev}/include include/heimdal
  56     remove="-isystem ${heimdal.dev}/include "
  57     NIX_CFLAGS_COMPILE=''${NIX_CFLAGS_COMPILE//"''$remove"/}
  58     NIX_CFLAGS_COMPILE+=" -isystem $(pwd)/include";
  59
  60     # add default config header for heimdal
  61     cp ${heimdalConfigHeader} include/heim_threads.h
  62   '';
  63
  64   meta = with lib; {
  65     description = "SMB module for Greenbone Community Edition";
  66     homepage = "https://github.com/greenbone/openvas-smb";
  67     license = licenses.gpl2Only;
  68     maintainers = with maintainers; [ mi-ael ];
  69     mainProgram = "wmic";
  70     platforms = platforms.linux;
  71   };
  72 }