pkgs/by-name/pd/pdf2djvu/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitHub,
   5   autoreconfHook,
   6   gettext,
   7   libtool,
   8   pkg-config,
   9   djvulibre,
  10   exiv2,
  11   fontconfig,
  12   graphicsmagick,
  13   libjpeg,
  14   libuuid,
  15   poppler,
  16 }:
  17
  18 stdenv.mkDerivation rec {
  19   version = "0.9.19";
  20   pname = "pdf2djvu";
  21
  22   src = fetchFromGitHub {
  23     owner = "jwilk";
  24     repo = "pdf2djvu";
  25     rev = version;
  26     sha256 = "sha256-j4mYdmLZ56qTA1KbWBjBvyTyLaeuIITKYsALRIO7lj0=";
  27   };
  28
  29   nativeBuildInputs = [
  30     autoreconfHook
  31     pkg-config
  32   ];
  33
  34   buildInputs = [
  35     djvulibre
  36     exiv2
  37     fontconfig
  38     graphicsmagick
  39     libjpeg
  40     libuuid
  41     poppler
  42   ];
  43
  44   postPatch = ''
  45     substituteInPlace private/autogen \
  46       --replace /usr/share/gettext ${gettext}/share/gettext \
  47       --replace /usr/share/libtool ${libtool}/share/libtool
  48
  49     substituteInPlace configure.ac \
  50       --replace '$djvulibre_bin_path' ${djvulibre.bin}/bin
  51   '';
  52
  53   preAutoreconf = ''
  54     private/autogen
  55   '';
  56
  57   enableParallelBuilding = true;
  58
  59   # Required by Poppler on darwin
  60   # https://github.com/jwilk/pdf2djvu/commit/373e065faf2f0d868a3700788d20a96e9528bb12
  61   CXXFLAGS = "-std=c++17";
  62
  63   meta = with lib; {
  64     description = "Creates djvu files from PDF files";
  65     homepage = "https://jwilk.net/software/pdf2djvu";
  66     license = licenses.gpl2Only;
  67     maintainers = with maintainers; [ pSub ];
  68     mainProgram = "pdf2djvu";
  69   };
  70 }