pkgs/by-name/pd/pdfchain/package.nix

   1 { lib, stdenv, fetchurl, fetchDebianPatch
   2 , autoconf, gtkmm3, glib, pdftk, pkg-config, wrapGAppsHook3
   3 }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "pdfchain";
   7   version = "0.4.4.2";
   8
   9   src = fetchurl {
  10     url = "mirror://sourceforge/${pname}/${pname}-${version}/${pname}-${version}.tar.gz";
  11     hash = "sha256-Hu4Pk9voyc75+f5OwKEOCkXKjN5nzWzv+izmyEN1Lz0=";
  12   };
  13
  14   nativeBuildInputs = [
  15     pkg-config wrapGAppsHook3 autoconf
  16   ];
  17
  18   buildInputs = [
  19     gtkmm3 pdftk glib
  20   ];
  21
  22   patches = let
  23     fetchDebianPatch' = args: fetchDebianPatch ({
  24       inherit pname;
  25       version = "1:0.4.4.2";
  26       debianRevision = "2";
  27     } // args);
  28   in
  29   [
  30     (fetchDebianPatch' {
  31       patch = "fix_crash_on_startup";
  32       hash = "sha256-1UyMHHGrmUIFhY53ILdMMsyocSIbcV6CKQ7sLVNhNQw=";
  33     })
  34     (fetchDebianPatch' {
  35       patch = "fix_desktop_file";
  36       hash = "sha256-L6lhUs7GqVN1XOQO6bbz6BT29n4upsJtlHCAIGzk1Bw=";
  37     })
  38     (fetchDebianPatch' {
  39       patch = "fix_spelling";
  40       hash = "sha256-sOUUslPfcOo2K3zuaLcux+CNdgfWM0phsfe6g4GUFes=";
  41     })
  42   ];
  43
  44   postPatch = ''
  45     substituteInPlace src/constant.h \
  46         --replace '"pdftk"' '"${pdftk}/bin/pdftk"' \
  47         --replace "/usr/share" "$out/share"
  48   '';
  49
  50   meta = with lib; {
  51     description = "Graphical user interface for the PDF Toolkit (PDFtk)";
  52     homepage = "https://pdfchain.sourceforge.io";
  53     license = licenses.gpl3Plus;
  54     maintainers = with maintainers; [ hqurve ];
  55     platforms = platforms.unix;
  56     mainProgram = "pdfchain";
  57   };
  58 }