pkgs/by-name/po/pokemmo-installer/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitLab,
   5   makeWrapper,
   6   coreutils,
   7   findutils,
   8   gnugrep,
   9   jre,
  10   openssl,
  11   util-linux,
  12   wget,
  13   which,
  14   zenity,
  15   libGL,
  16   libpulseaudio,
  17   nix-update-script,
  18 }:
  19
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "pokemmo-installer";
  22   version = "1.4.8";
  23
  24   src = fetchFromGitLab {
  25     owner = "coringao";
  26     repo = "pokemmo-installer";
  27     rev = "refs/tags/${finalAttrs.version}";
  28     hash = "sha256-uSbnXBpkeGM9X6DU7AikT7hG/emu67PXuGdm6xfB8To=";
  29   };
  30
  31   nativeBuildInputs = [ makeWrapper ];
  32
  33   installFlags = [
  34     "PREFIX=${placeholder "out"}"
  35
  36     # BINDIR defaults to $(PREFIX)/games
  37     "BINDIR=${placeholder "out"}/bin"
  38   ];
  39
  40   postFixup = ''
  41     wrapProgram "$out/bin/pokemmo-installer" \
  42       --prefix PATH : ${
  43         lib.makeBinPath [
  44           coreutils
  45           findutils
  46           gnugrep
  47           jre
  48           openssl
  49           util-linux
  50           wget
  51           which
  52           zenity
  53         ]
  54       } \
  55       --prefix LD_LIBRARY_PATH : ${
  56         lib.makeLibraryPath [
  57           libGL
  58           libpulseaudio
  59         ]
  60       }
  61   '';
  62
  63   passthru.updateScript = nix-update-script { };
  64
  65   meta = with lib; {
  66     description = "Installer and Launcher for the PokeMMO emulator";
  67     homepage = "https://pokemmo.eu";
  68     license = licenses.gpl3Only;
  69     maintainers = with maintainers; [ kira-bruneau ];
  70     platforms = platforms.linux;
  71     mainProgram = "pokemmo-installer";
  72   };
  73 })