pkgs/by-name/po/polkit/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , pkg-config
   5 , glib
   6 , expat
   7 , pam
   8 , meson
   9 , mesonEmulatorHook
  10 , ninja
  11 , perl
  12 , python3
  13 , gettext
  14 , duktape
  15 , gobject-introspection
  16 , libxslt
  17 , docbook-xsl-nons
  18 , dbus
  19 , docbook_xml_dtd_412
  20 , gtk-doc
  21 , coreutils
  22 , fetchpatch
  23 , useSystemd ? lib.meta.availableOn stdenv.hostPlatform systemdMinimal
  24 , systemdMinimal
  25 , elogind
  26 , buildPackages
  27 , withIntrospection ? lib.meta.availableOn stdenv.hostPlatform gobject-introspection && stdenv.hostPlatform.emulatorAvailable buildPackages
  28 # A few tests currently fail on musl (polkitunixusertest, polkitunixgrouptest, polkitidentitytest segfault).
  29 # Not yet investigated; it may be due to the "Make netgroup support optional"
  30 # patch not updating the tests correctly yet, or doing something wrong,
  31 # or being unrelated to that.
  32 , doCheck ? (stdenv.hostPlatform.isLinux && !stdenv.hostPlatform.isMusl)
  33 }:
  34
  35 let
  36   system = "/run/current-system/sw";
  37   setuid = "/run/wrappers/bin";
  38 in
  39 stdenv.mkDerivation rec {
  40   pname = "polkit";
  41   version = "124";
  42
  43   outputs = [ "bin" "dev" "out" ]; # small man pages in $bin
  44
  45   # Tarballs do not contain subprojects.
  46   src = fetchFromGitHub {
  47     owner = "polkit-org";
  48     repo = "polkit";
  49     rev = version;
  50     hash = "sha256-Vc9G2xK6U1cX+xW2BnKp3oS/ACbSXS/lztbFP5oJOlM=";
  51   };
  52
  53   patches = [
  54     # Allow changing base for paths in pkg-config file as before.
  55     # https://gitlab.freedesktop.org/polkit/polkit/-/merge_requests/100
  56     ./0001-build-Use-datarootdir-in-Meson-generated-pkg-config-.patch
  57
  58     ./elogind.patch
  59
  60     # FIXME: remove in the next release
  61     # https://github.com/NixOS/nixpkgs/issues/18012
  62     (fetchpatch {
  63       url = "https://github.com/polkit-org/polkit/commit/f93c7466039ea3403e0576928aeb620b806d0cce.patch";
  64       sha256 = "sha256-cF0nNovYmyr+XixpBgQFF0A+oJeSPGZgTkgDQkQuof8=";
  65     })
  66   ];
  67
  68   depsBuildBuild = [
  69     pkg-config
  70   ];
  71
  72   nativeBuildInputs = [
  73     glib
  74     pkg-config
  75     gettext
  76     meson
  77     ninja
  78     perl
  79
  80     # man pages
  81     libxslt
  82     docbook-xsl-nons
  83     docbook_xml_dtd_412
  84   ] ++ lib.optionals withIntrospection [
  85     gobject-introspection
  86     gtk-doc
  87   ] ++ lib.optionals (withIntrospection && !stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
  88     mesonEmulatorHook
  89   ];
  90
  91   buildInputs = [
  92     expat
  93     pam
  94     dbus
  95     duktape
  96   ] ++ lib.optionals stdenv.hostPlatform.isLinux [
  97     # On Linux, fall back to elogind when systemd support is off.
  98     (if useSystemd then systemdMinimal else elogind)
  99   ];
 100
 101   propagatedBuildInputs = [
 102     glib # in .pc Requires
 103   ];
 104
 105   nativeCheckInputs = [
 106     dbus
 107     (python3.pythonOnBuildForHost.withPackages (pp: with pp; [
 108       dbus-python
 109       (python-dbusmock.overridePythonAttrs (attrs: {
 110         # Avoid dependency cycle.
 111         doCheck = false;
 112       }))
 113     ]))
 114   ];
 115
 116   env = {
 117     PKG_CONFIG_SYSTEMD_SYSTEMDSYSTEMUNITDIR = "${placeholder "out"}/lib/systemd/system";
 118     PKG_CONFIG_SYSTEMD_SYSUSERS_DIR = "${placeholder "out"}/lib/sysusers.d";
 119
 120     # HACK: We want to install policy files files to $out/share but polkit
 121     # should read them from /run/current-system/sw/share on a NixOS system.
 122     # Similarly for config files in /etc.
 123     # With autotools, it was possible to override Make variables
 124     # at install time but Meson does not support this
 125     # so we need to convince it to install all files to a temporary
 126     # location using DESTDIR and then move it to proper one in postInstall.
 127     DESTDIR = "dest";
 128   } // lib.optionalAttrs stdenv.cc.isGNU {
 129     NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
 130   };
 131
 132   mesonFlags = [
 133     "--datadir=${system}/share"
 134     "--sysconfdir=/etc"
 135     "-Dpolkitd_user=polkituser" #TODO? <nixos> config.ids.uids.polkituser
 136     "-Dos_type=redhat" # only affects PAM includes
 137     "-Dintrospection=${lib.boolToString withIntrospection}"
 138     "-Dtests=${lib.boolToString doCheck}"
 139     "-Dgtk_doc=${lib.boolToString withIntrospection}"
 140     "-Dman=true"
 141   ] ++ lib.optionals stdenv.hostPlatform.isLinux [
 142     "-Dsession_tracking=${if useSystemd then "libsystemd-login" else "libelogind"}"
 143   ];
 144
 145
 146   inherit doCheck;
 147
 148   postPatch = ''
 149     patchShebangs test/polkitbackend/polkitbackendjsauthoritytest-wrapper.py
 150
 151     # ‘libpolkit-agent-1.so’ should call the setuid wrapper on
 152     # NixOS.  Hard-coding the path is kinda ugly.  Maybe we can just
 153     # call through $PATH, but that might have security implications.
 154     substituteInPlace src/polkitagent/polkitagentsession.c \
 155       --replace   'PACKAGE_PREFIX "/lib/polkit-1/'   '"${setuid}/'
 156     substituteInPlace test/data/etc/polkit-1/rules.d/10-testing.rules \
 157       --replace   /bin/true ${coreutils}/bin/true \
 158       --replace   /bin/false ${coreutils}/bin/false
 159   '';
 160
 161   postConfigure = lib.optionalString doCheck ''
 162     # Unpacked by meson
 163     chmod +x subprojects/mocklibc-1.0/bin/mocklibc
 164     patchShebangs subprojects/mocklibc-1.0/bin/mocklibc
 165   '';
 166
 167   checkPhase = ''
 168     runHook preCheck
 169
 170     # tests need access to the system bus
 171     dbus-run-session --config-file=${./system_bus.conf} -- sh -c 'DBUS_SYSTEM_BUS_ADDRESS=$DBUS_SESSION_BUS_ADDRESS meson test --print-errorlogs'
 172
 173     runHook postCheck
 174   '';
 175
 176   postInstall = ''
 177     # Move stuff from DESTDIR to proper location.
 178     # We need to be careful with the ordering to merge without conflicts.
 179     for o in $(getAllOutputNames); do
 180         mv "$DESTDIR/''${!o}" "''${!o}"
 181     done
 182     mv "$DESTDIR/etc" "$out"
 183     mv "$DESTDIR${system}/share"/* "$out/share"
 184     # Ensure we did not forget to install anything.
 185     rmdir --parents --ignore-fail-on-non-empty "$DESTDIR${builtins.storeDir}" "$DESTDIR${system}/share"
 186     ! test -e "$DESTDIR"
 187   '';
 188
 189   meta = with lib; {
 190     homepage = "https://github.com/polkit-org/polkit";
 191     description = "Toolkit for defining and handling the policy that allows unprivileged processes to speak to privileged processes";
 192     license = licenses.lgpl2Plus;
 193     platforms = platforms.linux;
 194     badPlatforms = [
 195       # mandatory libpolkit-gobject shared library
 196       lib.systems.inspect.platformPatterns.isStatic
 197     ];
 198     maintainers = teams.freedesktop.members ++ (with maintainers; [ ]);
 199   };
 200 }