pkgs/by-name/po/polymake/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , gmp
   5 , mpfr
   6 , flint
   7 , boost
   8 , bliss
   9 , ppl
  10 , singular
  11 , cddlib
  12 , lrs
  13 , nauty
  14 , ninja
  15 , ant
  16 , openjdk
  17 , perl
  18 , perlPackages
  19 , makeWrapper
  20 }:
  21
  22 # polymake compiles its own version of sympol and atint because we
  23 # don't have those packages. other missing optional dependencies:
  24 # javaview, libnormaliz, scip, soplex, jreality.
  25
  26 stdenv.mkDerivation rec {
  27   pname = "polymake";
  28   version = "4.13";
  29
  30   src = fetchurl {
  31     # "The minimal version is a packager friendly version which omits
  32     # the bundled sources of cdd, lrs, libnormaliz, nauty and jReality."
  33     url = "https://polymake.org/lib/exe/fetch.php/download/polymake-${version}-minimal.tar.bz2";
  34     sha256 = "sha256-862s0GO56mDV6cN8YYP127dFiwyzSR66Pvw48gxWXOs=";
  35   };
  36
  37   nativeBuildInputs = [
  38     makeWrapper
  39     ninja
  40     ant
  41     perl
  42   ];
  43
  44   buildInputs = [
  45     perl
  46     gmp
  47     mpfr
  48     flint
  49     boost
  50     bliss
  51     ppl
  52     singular
  53     cddlib
  54     lrs
  55     nauty
  56     openjdk
  57   ] ++ (with perlPackages; [
  58     JSON
  59     TermReadLineGnu
  60     TermReadKey
  61     XMLSAX
  62   ]);
  63
  64   ninjaFlags = [ "-C" "build/Opt" ];
  65
  66   postInstall = ''
  67     for i in "$out"/bin/*; do
  68       wrapProgram "$i" --prefix PERL5LIB : "$PERL5LIB"
  69     done
  70   '';
  71
  72   meta = with lib; {
  73     description = "Software for research in polyhedral geometry";
  74     homepage = "https://www.polymake.org/doku.php";
  75     changelog = "https://github.com/polymake/polymake/blob/V${version}/ChangeLog";
  76     license = licenses.gpl2Plus;
  77     maintainers = teams.sage.members;
  78     platforms = platforms.linux;
  79   };
  80 }