pkgs/by-name/po/postman/darwin.nix

   1 { stdenvNoCC
   2 , fetchurl
   3 , unzip
   4 , pname
   5 , version
   6 , meta
   7 }:
   8
   9 let
  10   appName = "Postman.app";
  11   dist = {
  12     aarch64-darwin = {
  13       arch = "arm64";
  14       sha256 = "sha256-V+JLXl12DnwZlPF0qNs2lQqRpWbSDiPXDTtl4FGcZcM=";
  15     };
  16
  17     x86_64-darwin = {
  18       arch = "64";
  19       sha256 = "sha256-l7J4Rrq+kUyk+0Chq5qo50K1VXC/7E3FC/hQ1DQ0PGA=";
  20     };
  21   }.${stdenvNoCC.hostPlatform.system} or (throw "Unsupported system: ${stdenvNoCC.hostPlatform.system}");
  22
  23 in
  24
  25 stdenvNoCC.mkDerivation {
  26   inherit pname version meta;
  27
  28   src = fetchurl {
  29     url = "https://dl.pstmn.io/download/version/${version}/osx_${dist.arch}";
  30     inherit (dist) sha256;
  31     name = "${pname}-${version}.zip";
  32   };
  33
  34   nativeBuildInputs = [ unzip ];
  35
  36   # Postman is notarized on macOS. Running the fixup phase will change the shell scripts embedded
  37   # in the bundle, which causes the notarization check to fail on macOS 13+.
  38   # See https://eclecticlight.co/2022/06/17/app-security-changes-coming-in-ventura/ for more information.
  39   dontFixup = true;
  40
  41   sourceRoot = appName;
  42
  43   installPhase = ''
  44     runHook preInstall
  45     mkdir -p $out/{Applications/${appName},bin}
  46     cp -R . $out/Applications/${appName}
  47     cat > $out/bin/${pname} << EOF
  48     #!${stdenvNoCC.shell}
  49     open -na $out/Applications/${appName} --args "$@"
  50     EOF
  51     chmod +x $out/bin/${pname}
  52     runHook postInstall
  53   '';
  54 }