pkgs/by-name/po/potreeconverter/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , boost
   6 , tbb
   7 , makeWrapper
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "PotreeConverter";
  12   version = "unstable-2023-02-27";
  13
  14   src = fetchFromGitHub {
  15     owner = "potree";
  16     repo = "PotreeConverter";
  17     rev = "af4666fa1090983d8ce7c11dcf49ba19eda90995";
  18     sha256 = "sha256-QYNY+/v6mBEJFiv3i2QS+zqkgWJqeqXSqNoh+ChAiQA=";
  19   };
  20
  21   buildInputs = [
  22     boost
  23     tbb
  24   ];
  25
  26   nativeBuildInputs = [
  27     makeWrapper
  28     cmake
  29   ];
  30
  31   postPatch = ''
  32     runHook prePatch
  33
  34     substituteInPlace ./CMakeLists.txt \
  35       --replace "find_package(TBB REQUIRED)" ""
  36
  37     # prevent inheriting permissions from /nix/store when copying
  38     substituteInPlace Converter/src/main.cpp --replace \
  39       'fs::copy(templateDir, pagedir, fs::copy_options::overwrite_existing | fs::copy_options::recursive)' 'string cmd = "cp --no-preserve=mode -r " + templateDir + " " + pagedir; system(cmd.c_str());'
  40   '';
  41
  42   # The upstream build system does not provide an install target.
  43   installPhase = ''
  44     runHook preInstall
  45
  46     mkdir -p $out/{bin,lib}
  47     mv liblaszip.so $out/lib
  48     mv PotreeConverter $out/bin
  49     ln -s $out/bin/PotreeConverter $out/bin/potreeconverter
  50
  51     # Create an empty wrapper, since PotreeConverter segfaults if called via
  52     # $PATH rather than absolute path. An empty wrapper forces an absolute path
  53     # on each invocation
  54     wrapProgram $out/bin/PotreeConverter
  55
  56     runHook postInstall
  57   '';
  58
  59   postFixup = ''
  60     ln -s $src/resources $out/bin/resources
  61   '';
  62
  63   meta = with lib; {
  64     description = "Create multi res point cloud to use with potree";
  65     homepage = "https://github.com/potree/PotreeConverter";
  66     license = licenses.bsd2;
  67     maintainers = with maintainers; [ matthewcroughan ];
  68     platforms = with platforms; linux;
  69   };
  70 }