pkgs/by-name/pr/proton-ge-bin/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchzip,
   5   writeScript,
   6 }:
   7 stdenvNoCC.mkDerivation (finalAttrs: {
   8   pname = "proton-ge-bin";
   9   version = "GE-Proton9-20";
  10
  11   src = fetchzip {
  12     url = "https://github.com/GloriousEggroll/proton-ge-custom/releases/download/${finalAttrs.version}/${finalAttrs.version}.tar.gz";
  13     hash = "sha256-1twCv81KO1fcRcIb4H7VtAjtcKrX+DymsYdf885eOWo=";
  14   };
  15
  16   outputs = [
  17     "out"
  18     "steamcompattool"
  19   ];
  20
  21   buildCommand = ''
  22     runHook preBuild
  23
  24     # Make it impossible to add to an environment. You should use the appropriate NixOS option.
  25     # Also leave some breadcrumbs in the file.
  26     echo "${finalAttrs.pname} should not be installed into environments. Please use programs.steam.extraCompatPackages instead." > $out
  27
  28     mkdir $steamcompattool
  29     ln -s $src/* $steamcompattool
  30     rm $steamcompattool/{compatibilitytool.vdf,proton,version}
  31     cp $src/{compatibilitytool.vdf,proton,version} $steamcompattool
  32
  33     sed -i -r 's|GE-Proton[0-9]*-[0-9]*|GE-Proton|' $steamcompattool/compatibilitytool.vdf
  34     sed -i -r 's|GE-Proton[0-9]*-[0-9]*|GE-Proton|' $steamcompattool/proton
  35
  36     runHook postBuild
  37   '';
  38
  39   /*
  40     We use the created releases, and not the tags, for the update script as nix-update loads releases.atom
  41     that contains both. Sometimes upstream pushes the tags but the Github releases don't get created due to
  42     CI errors. Last time this happened was on 8-33, where a tag was created but no releases were created.
  43     As of 2024-03-13, there have been no announcements indicating that the CI has been fixed, and thus
  44     we avoid nix-update-script and use our own update script instead.
  45     See: <https://github.com/NixOS/nixpkgs/pull/294532#issuecomment-1987359650>
  46   */
  47   passthru.updateScript = writeScript "update-proton-ge" ''
  48     #!/usr/bin/env nix-shell
  49     #!nix-shell -i bash -p curl jq common-updater-scripts
  50     repo="https://api.github.com/repos/GloriousEggroll/proton-ge-custom/releases"
  51     version="$(curl -sL "$repo" | jq 'map(select(.prerelease == false)) | .[0].tag_name' --raw-output)"
  52     update-source-version proton-ge-bin "$version"
  53   '';
  54
  55   meta = {
  56     description = ''
  57       Compatibility tool for Steam Play based on Wine and additional components.
  58
  59       (This is intended for use in the `programs.steam.extraCompatPackages` option only.)
  60     '';
  61     homepage = "https://github.com/GloriousEggroll/proton-ge-custom";
  62     license = lib.licenses.bsd3;
  63     maintainers = with lib.maintainers; [
  64       NotAShelf
  65       shawn8901
  66     ];
  67     platforms = [ "x86_64-linux" ];
  68     sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
  69   };
  70 })