pkgs/by-name/ps/psqlodbc/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   nix-update-script,
   6   autoreconfHook,
   7   libpq,
   8   openssl,
   9   withLibiodbc ? false,
  10   libiodbc,
  11   withUnixODBC ? true,
  12   unixODBC,
  13 }:
  14
  15 assert lib.xor withLibiodbc withUnixODBC;
  16
  17 stdenv.mkDerivation rec {
  18   pname = "psqlodbc";
  19   version = "${builtins.replaceStrings [ "_" ] [ "." ] (lib.strings.removePrefix "REL-" src.tag)}";
  20
  21   src = fetchFromGitHub {
  22     owner = "postgresql-interfaces";
  23     repo = "psqlodbc";
  24     tag = "REL-17_00_0002";
  25     hash = "sha256-zCjoX+Ew8sS5TWkFSgoqUN5ukEF38kq+MdfgCQQGv9w=";
  26   };
  27
  28   buildInputs =
  29     [
  30       libpq
  31       openssl
  32     ]
  33     ++ lib.optional withLibiodbc libiodbc
  34     ++ lib.optional withUnixODBC unixODBC;
  35
  36   nativeBuildInputs = [
  37     autoreconfHook
  38   ];
  39
  40   passthru =
  41     {
  42       updateScript = nix-update-script { };
  43     }
  44     // lib.optionalAttrs withUnixODBC {
  45       fancyName = "PostgreSQL";
  46       driver = "lib/psqlodbcw.so";
  47     };
  48
  49   configureFlags = [
  50     "--with-libpq=${lib.getDev libpq}"
  51   ] ++ lib.optional withLibiodbc "--with-iodbc=${libiodbc}";
  52
  53   meta = with lib; {
  54     homepage = "https://odbc.postgresql.org/";
  55     description = "ODBC driver for PostgreSQL";
  56     license = licenses.lgpl2;
  57     platforms = platforms.unix;
  58     maintainers = libpq.meta.maintainers;
  59   };
  60 }