pkgs/by-name/rs/rsmangler/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   testers,
   6   ruby,
   7 }:
   8
   9 stdenvNoCC.mkDerivation (finalAttrs: {
  10   pname = "rsmangler";
  11   version = "1.5-unstable-2019-07-24";
  12
  13   src = fetchFromGitHub {
  14     owner = "digininja";
  15     repo = "RSMangler";
  16     rev = "e85da7d4a6e6241a92389aecf376077adc7544c3";
  17     hash = "sha256-DN20XzrlkunLyk4nkgytUJEtCOlFjWUUUAQ416l3Aug=";
  18   };
  19
  20   buildInputs = [ ruby ];
  21
  22   postPatch = ''
  23     substituteInPlace rsmangler.rb \
  24       --replace-quiet ./rsmangler.rb rsmangler \
  25       --replace-quiet rsmangler.rb rsmangler
  26   '';
  27
  28   postInstall = ''
  29     install -Dm555 rsmangler.rb $out/bin/rsmangler
  30   '';
  31
  32   passthru.tests.version = testers.testVersion {
  33     package = finalAttrs.finalPackage;
  34     command = "rsmangler --help";
  35     version = "rsmangler v ${lib.versions.majorMinor finalAttrs.version}";
  36   };
  37
  38   meta = with lib; {
  39     description = "Perform various manipulations on the wordlists";
  40     homepage = "https://github.com/digininja/RSMangler";
  41     license = licenses.cc-by-sa-20;
  42     mainProgram = "rsmangler";
  43     maintainers = with maintainers; [ d3vil0p3r ];
  44     platforms = ruby.meta.platforms;
  45   };
  46 })