pkgs/by-name/sc/scala-update/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   coursier,
   5   buildGraalvmNativeImage,
   6 }:
   7
   8 let
   9   baseName = "scala-update";
  10   version = "0.2.2";
  11   deps = stdenv.mkDerivation {
  12     name = "${baseName}-deps-${version}";
  13     buildCommand = ''
  14       export COURSIER_CACHE=$(pwd)
  15       ${coursier}/bin/cs fetch io.github.kitlangton:scala-update_2.13:${version} > deps
  16       mkdir -p $out/share/java
  17       cp $(< deps) $out/share/java/
  18     '';
  19     outputHashMode = "recursive";
  20     outputHashAlgo = "sha256";
  21     outputHash = "kNnFzzHn+rFq4taqRYjBYaDax0MHW+vIoSFVN3wxA8M=";
  22   };
  23 in
  24 buildGraalvmNativeImage {
  25   pname = baseName;
  26   inherit version;
  27
  28   buildInputs = [ deps ];
  29
  30   src = "${deps}/share/java/${baseName}_2.13-${version}.jar";
  31
  32   extraNativeImageBuildArgs = [
  33     "--no-fallback"
  34     "--enable-url-protocols=https"
  35     "update.Main"
  36   ];
  37
  38   buildPhase = ''
  39     runHook preBuild
  40
  41     native-image ''${nativeImageBuildArgs[@]} -cp $(JARS=("${deps}/share/java"/*.jar); IFS=:; echo "''${JARS[*]}")
  42
  43     runHook postBuild
  44   '';
  45
  46   installCheckPhase = ''
  47     $out/bin/${baseName} --version | grep -q "${version}"
  48   '';
  49
  50   meta = with lib; {
  51     description = "Update your Scala dependencies interactively";
  52     homepage = "https://github.com/kitlangton/scala-update";
  53     license = licenses.asl20;
  54     maintainers = [ maintainers.rtimush ];
  55   };
  56 }