pkgs/by-name/sc/scid-vs-pc/package.nix

   1 { lib, fetchurl, tcl, tk, libX11, zlib, makeWrapper, which, makeDesktopItem }:
   2
   3 tcl.mkTclDerivation rec {
   4   pname = "scid-vs-pc";
   5   version = "4.25";
   6
   7   src = fetchurl {
   8     url = "mirror://sourceforge/scidvspc/scid_vs_pc-${version}.tgz";
   9     hash = "sha256-YZsBwIp5ouGk75wsAywuYyNSeNjCAx0iWgiA7YmUmnk=";
  10   };
  11
  12   postPatch = ''
  13     substituteInPlace configure Makefile.conf \
  14       --replace "~/.fonts" "$out/share/fonts/truetype/Scid" \
  15       --replace "which fc-cache" "false"
  16   '';
  17
  18   nativeBuildInputs = [ makeWrapper which ];
  19   buildInputs = [ tk libX11 zlib ];
  20
  21   configureFlags = [
  22     "BINDIR=${placeholder "out"}/bin"
  23     "SHAREDIR=${placeholder "out"}/share"
  24   ];
  25
  26   postInstall = ''
  27     mkdir -p $out/share/applications
  28     cp $desktopItem/share/applications/* $out/share/applications/
  29
  30     install -D icons/scid.png "$out"/share/icons/hicolor/128x128/apps/scid.png
  31   '';
  32
  33   desktopItem = makeDesktopItem {
  34     name = "scid-vs-pc";
  35     desktopName = "Scid vs. PC";
  36     genericName = "Chess Database";
  37     comment = meta.description;
  38     icon = "scid";
  39     exec = "scid";
  40     categories = [ "Game" "BoardGame" ];
  41   };
  42
  43   meta = with lib; {
  44     description = "Chess database with play and training functionality";
  45     homepage = "https://scidvspc.sourceforge.net/";
  46     license = lib.licenses.gpl2Only;
  47     maintainers = [ maintainers.paraseba ];
  48     platforms = lib.platforms.linux;
  49   };
  50 }