pkgs/by-name/sc/screenkey/package.nix

   1 {
   2   lib,
   3   fetchFromGitLab,
   4   wrapGAppsHook3,
   5   xorg,
   6   gobject-introspection,
   7   gtk3,
   8   libappindicator-gtk3,
   9   slop,
  10   python3,
  11 }:
  12
  13 python3.pkgs.buildPythonApplication rec {
  14   pname = "screenkey";
  15   version = "1.5";
  16
  17   src = fetchFromGitLab {
  18     owner = pname;
  19     repo = pname;
  20     rev = "v${version}";
  21     hash = "sha256-kWktKzRyWHGd1lmdKhPwrJoSzAIN2E5TKyg30uhM4Ug=";
  22   };
  23
  24   nativeBuildInputs = [
  25     wrapGAppsHook3
  26     # for setup hook
  27     gobject-introspection
  28   ];
  29
  30   buildInputs = [
  31     gtk3
  32     libappindicator-gtk3
  33   ];
  34
  35   propagatedBuildInputs = with python3.pkgs; [
  36     babel
  37     pycairo
  38     pygobject3
  39     dbus-python
  40   ];
  41
  42   # Prevent double wrapping because of wrapGAppsHook3
  43   dontWrapGApps = true;
  44
  45   preFixup = ''
  46     makeWrapperArgs+=(
  47       --prefix PATH ":" "${lib.makeBinPath [ slop ]}"
  48       "''${gappsWrapperArgs[@]}"
  49       )
  50   '';
  51
  52   # screenkey does not have any tests
  53   doCheck = false;
  54
  55   # Fix CDLL python calls for non absolute paths of xorg libraries
  56   postPatch = ''
  57     substituteInPlace Screenkey/xlib.py \
  58       --replace libX11.so.6 ${lib.getLib xorg.libX11}/lib/libX11.so.6 \
  59       --replace libXtst.so.6 ${lib.getLib xorg.libXtst}/lib/libXtst.so.6
  60   '';
  61
  62   meta = with lib; {
  63     homepage = "https://www.thregr.org/~wavexx/software/screenkey/";
  64     description = "Screencast tool to display your keys inspired by Screenflick";
  65     license = licenses.gpl3Plus;
  66     platforms = platforms.linux;
  67     maintainers = [ maintainers.rasendubi ];
  68     mainProgram = "screenkey";
  69   };
  70 }