pkgs/by-name/sh/shepherd/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , fetchYarnDeps
   5 , makeWrapper
   6 , nodejs
   7 , fixup-yarn-lock
   8 , yarn
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12   pname = "shepherd";
  13   version = "1.16.0";
  14
  15   src = fetchFromGitHub {
  16     owner = "NerdWalletOSS";
  17     repo = "shepherd";
  18     rev = "v${version}";
  19     hash = "sha256-LY8Vde4YpGuKnQ5UnSOpsQDY7AOyZRziUrfZb5dRiX4=";
  20   };
  21
  22   offlineCache = fetchYarnDeps {
  23     yarnLock = "${src}/yarn.lock";
  24     hash = "sha256-tJXJ8ePr5ArAV+0JcuJsTo/B2PUcgsXfZrSDCpna/9k=";
  25   };
  26
  27   nativeBuildInputs  = [
  28     makeWrapper
  29     nodejs
  30     fixup-yarn-lock
  31     yarn
  32   ];
  33
  34   configurePhase = ''
  35     runHook preConfigure
  36
  37     export HOME=$(mktemp -d)
  38     yarn config --offline set yarn-offline-mirror "$offlineCache"
  39     fixup-yarn-lock yarn.lock
  40     yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
  41     patchShebangs node_modules
  42
  43     runHook postConfigure
  44   '';
  45
  46   buildPhase = ''
  47     runHook preBuild
  48
  49     yarn --offline build
  50
  51     runHook postBuild
  52   '';
  53
  54   installPhase = ''
  55     runHook preInstall
  56
  57     yarn --offline --production install
  58
  59     mkdir -p "$out/lib/node_modules/@nerdwallet/shepherd"
  60     cp -r . "$out/lib/node_modules/@nerdwallet/shepherd"
  61
  62     makeWrapper "${nodejs}/bin/node" "$out/bin/shepherd" \
  63       --add-flags "$out/lib/node_modules/@nerdwallet/shepherd/lib/cli.js"
  64
  65     runHook postInstall
  66   '';
  67
  68   meta = {
  69     changelog = "https://github.com/NerdWalletOSS/shepherd/blob/${src.rev}/CHANGELOG.md";
  70     description = "Utility for applying code changes across many repositories";
  71     homepage = "https://github.com/NerdWalletOSS/shepherd";
  72     license = lib.licenses.asl20;
  73     mainProgram = "shepherd";
  74     maintainers = with lib.maintainers; [ dbirks ];
  75     platforms = lib.platforms.all;
  76   };
  77 }