pkgs/by-name/sk/sketchybar/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   nix-update-script,
   6   apple-sdk_15,
   7   versionCheckHook,
   8 }:
   9
  10 let
  11   inherit (stdenv.hostPlatform) system;
  12
  13   target =
  14     {
  15       "aarch64-darwin" = "arm64";
  16       "x86_64-darwin" = "x86";
  17     }
  18     .${system} or (throw "Unsupported system: ${system}");
  19 in
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "sketchybar";
  22   version = "2.22.0";
  23
  24   src = fetchFromGitHub {
  25     owner = "FelixKratz";
  26     repo = "SketchyBar";
  27     rev = "v${finalAttrs.version}";
  28     hash = "sha256-0082rRSfIKJFTAzmJ65ItEdLSwjFks5ZkTlVZqaWKEw=";
  29   };
  30
  31   buildInputs = [
  32     apple-sdk_15
  33   ];
  34
  35   makeFlags = [ target ];
  36
  37   installPhase = ''
  38     runHook preInstall
  39
  40     mkdir -p $out/bin
  41     cp ./bin/sketchybar $out/bin/sketchybar
  42
  43     runHook postInstall
  44   '';
  45
  46   passthru.updateScript = nix-update-script { };
  47
  48   nativeInstallCheckInputs = [ versionCheckHook ];
  49   versionCheckProgramArg = "--version";
  50   doInstallCheck = true;
  51
  52   meta = {
  53     description = "Highly customizable macOS status bar replacement";
  54     homepage = "https://github.com/FelixKratz/SketchyBar";
  55     license = lib.licenses.gpl3;
  56     mainProgram = "sketchybar";
  57     maintainers = with lib.maintainers; [
  58       azuwis
  59       khaneliman
  60     ];
  61     platforms = lib.platforms.darwin;
  62   };
  63 })