pkgs/by-name/tc/tcp_wrappers/package.nix

   1 {
   2   fetchurl,
   3   lib,
   4   stdenv,
   5   libnsl,
   6 }:
   7
   8 let
   9   vanillaVersion = "7.6.q";
  10   patchLevel = "33";
  11 in
  12 stdenv.mkDerivation rec {
  13   pname = "tcp-wrappers";
  14   version = "${vanillaVersion}-${patchLevel}";
  15
  16   src = fetchurl {
  17     url = "mirror://debian/pool/main/t/tcp-wrappers/tcp-wrappers_${vanillaVersion}.orig.tar.gz";
  18     sha256 = "0p9ilj4v96q32klavx0phw9va21fjp8vpk11nbh6v2ppxnnxfhwm";
  19   };
  20
  21   debian = fetchurl {
  22     url = "mirror://debian/pool/main/t/tcp-wrappers/tcp-wrappers_${version}.debian.tar.xz";
  23     hash = "sha256-Lykjyu4hKDS/DqQ8JAFhKDffHrbJ9W1gjBKNpdaNRew=";
  24   };
  25
  26   prePatch = ''
  27     tar -xaf $debian
  28     patches="$(cat debian/patches/series | sed 's,^,debian/patches/,') $patches"
  29
  30     substituteInPlace Makefile --replace STRINGS STRINGDEFS
  31     substituteInPlace debian/patches/13_shlib_weaksym --replace STRINGS STRINGDEFS
  32   '';
  33
  34   # Fix __BEGIN_DECLS usage (even if it wasn't non-standard, this doesn't include sys/cdefs.h)
  35   patches = [ ./cdecls.patch ];
  36
  37   buildInputs = [ libnsl ];
  38
  39   makeFlags = [
  40     "REAL_DAEMON_DIR=$(out)/bin"
  41     "linux"
  42     "AR:=$(AR)"
  43   ];
  44
  45   installPhase = ''
  46     mkdir -p "$out/bin"
  47     cp -v safe_finger tcpd tcpdchk tcpdmatch try-from "$out/bin"
  48
  49     mkdir -p "$out/lib"
  50     cp -v shared/lib*.so* "$out/lib"
  51
  52     mkdir -p "$out/include"
  53     cp -v *.h "$out/include"
  54
  55     for i in 3 5 8;
  56     do
  57       mkdir -p "$out/man/man$i"
  58       cp *.$i "$out/man/man$i" ;
  59     done
  60   '';
  61
  62   meta = {
  63     description = "TCP Wrappers, a network logger, also known as TCPD or LOG_TCP";
  64
  65     longDescription = ''
  66       Wietse Venema's network logger, also known as TCPD or LOG_TCP.
  67       These programs log the client host name of incoming telnet, ftp,
  68       rsh, rlogin, finger etc. requests.  Security options are: access
  69       control per host, domain and/or service; detection of host name
  70       spoofing or host address spoofing; booby traps to implement an
  71       early-warning system.  The current version supports the System
  72       V.4 TLI network programming interface (Solaris, DG/UX) in
  73       addition to the traditional BSD sockets.
  74     '';
  75
  76     homepage = "ftp://ftp.porcupine.org/pub/security/index.html";
  77     license = "BSD-style";
  78     platforms = lib.platforms.linux;
  79   };
  80 }