pkgs/by-name/tu/tuntox/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   cscope,
   5   fetchFromGitHub,
   6   fetchpatch,
   7   git,
   8   libevent,
   9   libopus,
  10   libsodium,
  11   libtoxcore,
  12   libvpx,
  13   msgpack,
  14   pkg-config,
  15   python3,
  16   python3Packages,
  17 }:
  18
  19 stdenv.mkDerivation rec {
  20   pname = "tuntox";
  21   version = "0.0.10";
  22
  23   src = fetchFromGitHub {
  24     owner = "gjedeer";
  25     repo = pname;
  26     rev = version;
  27     sha256 = "sha256-c/0OxUH8iw8nRuVg4Fszf6Z/JiEV+m0B2ofzy81uFu8=";
  28   };
  29
  30   nativeBuildInputs = [
  31     cscope
  32     git
  33     pkg-config
  34   ];
  35
  36   buildInputs = [
  37     libopus
  38     libtoxcore
  39     libsodium
  40     libevent
  41     libvpx
  42     msgpack
  43     python3
  44   ];
  45
  46   pythonBuildInputs = with python3Packages; [
  47     jinja2
  48     requests
  49   ];
  50
  51   patches = [
  52     # https://github.com/gjedeer/tuntox/pull/67
  53     (fetchpatch {
  54       url = "https://github.com/gjedeer/tuntox/compare/a646402f42e120c7148d4de29dbdf5b09027a80a..365d2e5cbc0e3655fb64c204db0515f5f4cdf5a4.patch";
  55       sha256 = "sha256-P3uIRnV+pBi3s3agGYUMt2PZU4CRxx/DUR8QPVQ+UN8=";
  56     })
  57   ];
  58
  59   postPatch =
  60     ''
  61       substituteInPlace gitversion.h --replace '7d45afdf7d00a95a8c3687175e2b1669fa1f7745' '365d2e5cbc0e3655fb64c204db0515f5f4cdf5a4'
  62     ''
  63     + lib.optionalString stdenv.hostPlatform.isLinux ''
  64       substituteInPlace Makefile --replace ' -static ' ' '
  65       substituteInPlace Makefile --replace 'CC=gcc' ' '
  66     ''
  67     + lib.optionalString stdenv.hostPlatform.isDarwin ''
  68       substituteInPlace Makefile.mac --replace '.git/HEAD .git/index' ' '
  69       substituteInPlace Makefile.mac --replace '/usr/local/lib/libtoxcore.a' '${libtoxcore}/lib/libtoxcore.a'
  70       substituteInPlace Makefile.mac --replace '/usr/local/lib/libsodium.a' '${libsodium}/lib/libsodium.dylib'
  71       substituteInPlace Makefile.mac --replace 'CC=gcc' ' '
  72     '';
  73
  74   buildPhase =
  75     ''''
  76     + lib.optionalString stdenv.hostPlatform.isLinux ''
  77       make
  78     ''
  79     + lib.optionalString stdenv.hostPlatform.isDarwin ''
  80       make -f Makefile.mac tuntox
  81     '';
  82
  83   installPhase = ''
  84     mkdir -p $out/bin
  85     mv tuntox $out/bin/
  86   '';
  87
  88   doCheck = false;
  89
  90   meta = with lib; {
  91     description = "Tunnel TCP connections over the Tox protocol";
  92     mainProgram = "tuntox";
  93     homepage = "https://github.com/gjedeer/tuntox";
  94     license = licenses.gpl3;
  95     maintainers = with maintainers; [
  96       willcohen
  97     ];
  98     platforms = platforms.unix;
  99   };
 100 }