pkgs/by-name/tu/tuxtype/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   autoreconfHook,
   6   pkg-config,
   7   librsvg,
   8   libxml2,
   9   SDL,
  10   SDL_image,
  11   SDL_mixer,
  12   SDL_net,
  13   SDL_ttf,
  14   t4kcommon,
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   version = "1.8.3";
  19   pname = "tuxtype";
  20
  21   src = fetchFromGitHub {
  22     owner = "tux4kids";
  23     repo = "tuxtype";
  24     rev = "upstream/${version}";
  25     sha256 = "1i33rhi9gpzfml4hd73s18h6p2s8zcr26va2vwf2pqqd9fhdwpsg";
  26   };
  27
  28   postPatch = ''
  29     patchShebangs data/scripts/sed-linux.sh
  30     patchShebangs data/themes/asturian/scripts/sed-linux.sh
  31     patchShebangs data/themes/greek/scripts/sed-linux.sh
  32     patchShebangs data/themes/hungarian/scripts/sed-linux.sh
  33
  34     substituteInPlace Makefile.am \
  35       --replace "\$(MKDIR_P) -m 2755 " "\$(MKDIR_P) -m 755 " \
  36       --replace "chown root:games \$(DESTDIR)\$(pkglocalstatedir)/words" " "
  37
  38     # required until the following has been merged:
  39     # https://salsa.debian.org/tux4kids-pkg-team/tuxtype/merge_requests/1
  40     substituteInPlace configure.ac \
  41       --replace 'CFLAGS="$CFLAGS $SDL_IMAGE"' 'CFLAGS="$CFLAGS $SDL_IMAGE_CFLAGS"' \
  42       --replace 'PKG_CHECK_MODULES([SDL_ttf],' 'PKG_CHECK_MODULES([SDL_TTF],'
  43   '';
  44
  45   nativeBuildInputs = [
  46     autoreconfHook
  47     pkg-config
  48   ];
  49   buildInputs = [
  50     librsvg
  51     libxml2
  52     SDL
  53     SDL_image
  54     SDL_mixer
  55     SDL_net
  56     SDL_ttf
  57     t4kcommon
  58   ];
  59
  60   configureFlags = [ "--without-sdlpango" ];
  61
  62   meta = with lib; {
  63     description = "Educational Typing Tutor Game Starring Tux, the Linux Penguin";
  64     mainProgram = "tuxtype";
  65     homepage = "https://github.com/tux4kids/tuxtype";
  66     license = licenses.gpl3Plus;
  67     maintainers = [ maintainers.aanderse ];
  68     platforms = platforms.linux;
  69   };
  70 }