pkgs/by-name/un/unigine-valley/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4
   5   # Build-time dependencies
   6 , makeWrapper
   7 , file
   8 , makeDesktopItem
   9 , imagemagick
  10 , copyDesktopItems
  11
  12   # Runtime dependencies
  13 , fontconfig
  14 , freetype
  15 , libX11
  16 , libXext
  17 , libXinerama
  18 , libXrandr
  19 , libXrender
  20 , libglvnd
  21 , openal
  22 }:
  23
  24 let
  25   version = "1.0";
  26
  27   arch =
  28     if stdenv.hostPlatform.system == "x86_64-linux" then
  29       "x64"
  30     else if stdenv.hostPlatform.system == "i686-linux" then
  31       "x86"
  32     else
  33       throw "Unsupported platform ${stdenv.hostPlatform.system}";
  34 in
  35
  36 stdenv.mkDerivation rec {
  37   pname = "unigine-valley";
  38   inherit version;
  39
  40   src = fetchurl {
  41     url = "https://assets.unigine.com/d/Unigine_Valley-${version}.run";
  42     sha256 = "sha256-XwyL0kMRGFURgrq79fHCD7FOekB4lpckDcr1RkQ2YPQ=";
  43   };
  44
  45   sourceRoot = "Unigine_Valley-${version}";
  46   instPath = "lib/unigine/valley";
  47
  48   nativeBuildInputs = [ file makeWrapper imagemagick copyDesktopItems ];
  49
  50   libPath = lib.makeLibraryPath [
  51     stdenv.cc.cc # libstdc++.so.6
  52     fontconfig
  53     freetype
  54     libX11
  55     libXext
  56     libXinerama
  57     libXrandr
  58     libXrender
  59     libglvnd
  60     openal
  61   ];
  62
  63   unpackPhase = ''
  64     runHook preUnpack
  65
  66     cp $src extractor.run
  67     chmod +x extractor.run
  68     ./extractor.run --target $sourceRoot
  69
  70     runHook postUnpack
  71   '';
  72
  73   postPatch = ''
  74     # Patch ELF files.
  75     elfs=$(find bin -type f | xargs file | grep ELF | cut -d ':' -f 1)
  76     for elf in $elfs; do
  77       patchelf --set-interpreter ${stdenv.cc.libc}/lib/ld-linux-x86-64.so.2 $elf || true
  78     done
  79   '';
  80
  81   installPhase = ''
  82     runHook preInstall
  83
  84     instdir=$out/${instPath}
  85     mkdir -p $out/share/icons/hicolor $out/share/applications $out/bin $instdir/bin
  86
  87     # Install executables and libraries
  88     install -m 0755 bin/browser_${arch} $instdir/bin
  89     install -m 0755 bin/libApp{Stereo,Surround,Wall}_${arch}.so $instdir/bin
  90     install -m 0755 bin/libGPUMonitor_${arch}.so $instdir/bin
  91     install -m 0755 bin/libQt{Core,Gui,Network,WebKit,Xml}Unigine_${arch}.so.4 $instdir/bin
  92     install -m 0755 bin/libUnigine_${arch}.so $instdir/bin
  93     install -m 0755 bin/valley_${arch} $instdir/bin
  94     install -m 0755 valley $instdir
  95     install -m 0755 valley $out/bin/valley
  96
  97     # Install other files
  98     cp -R data documentation $instdir
  99
 100     # Install and wrap executable
 101     wrapProgram $out/bin/valley \
 102       --chdir "$instdir" \
 103       --prefix LD_LIBRARY_PATH : /run/opengl-driver/lib:$instdir/bin:$libPath
 104
 105     # Make desktop Icon
 106     convert $out/lib/unigine/valley/data/launcher/icon.png -resize 128x128 $out/share/icons/Valley.png
 107     for RES in 16 24 32 48 64 128 256
 108     do
 109         mkdir -p $out/share/icons/hicolor/"$RES"x"$RES"/apps
 110         convert $out/lib/unigine/valley/data/launcher/icon.png -resize "$RES"x"$RES" $out/share/icons/hicolor/"$RES"x"$RES"/apps/Valley.png
 111     done
 112
 113     runHook postInstall
 114   '';
 115
 116   desktopItems = [
 117     (makeDesktopItem {
 118       name = "Valley";
 119       exec = "valley";
 120       genericName = "A GPU Stress test tool from the UNIGINE";
 121       icon = "Valley";
 122       desktopName = "Valley Benchmark";
 123     })
 124   ];
 125
 126   stripDebugList = [ "${instPath}/bin" ];
 127
 128   meta = {
 129     description = "Unigine Valley GPU benchmarking tool";
 130     homepage = "https://unigine.com/products/benchmarks/valley/";
 131     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
 132     license = lib.licenses.unfree; # see also: $out/$instPath/documentation/License.pdf
 133     maintainers = [ ];
 134     platforms = [ "x86_64-linux" "i686-linux" ];
 135     mainProgram = "valley";
 136   };
 137 }
 138