pkgs/by-name/us/ustr/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchgit,
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "ustr";
   9   version = "1.0.4";
  10
  11   src = fetchgit {
  12     url = "http://www.and.org/ustr/ustr.git";
  13     rev = "v${finalAttrs.version}";
  14     hash = "sha256-pQrQy+S9fVFl8Mop4QmwEAXGiBSheQE4HgAZ4srFz64=";
  15   };
  16
  17   # Fixes bogus warnings that failed libsemanage
  18   patches = [ ./va_args.patch ];
  19
  20   # Work around gcc5 switch to gnu11
  21   env.NIX_CFLAGS_COMPILE = "-std=gnu89";
  22
  23   # Fix detection of stdint.h
  24   postPatch = ''
  25     substituteInPlace Makefile \
  26       --replace-fail "have_stdint_h=0" "have_stdint_h=1"
  27
  28     cat ustr-import.in | grep USTR_CONF
  29     substituteInPlace ustr-import.in \
  30       --replace-fail "USTR_CONF_HAVE_STDINT_H 0" "USTR_CONF_HAVE_STDINT_H 1"
  31   '';
  32
  33   makeFlags = [
  34     "prefix=${placeholder "out"}"
  35     "LDCONFIG=echo"
  36     "HIDE="
  37   ];
  38
  39   # Remove debug libraries
  40   postInstall = ''
  41     find $out/lib -name \*debug\* -delete
  42   '';
  43
  44   meta = {
  45     homepage = "http://www.and.org/ustr/";
  46     description = "Micro String API for C language";
  47     mainProgram = "ustr-import";
  48     license = lib.licenses.bsd2;
  49     maintainers = with lib.maintainers; [ sigmanificient ];
  50     platforms = lib.platforms.linux;
  51   };
  52 })