pkgs/by-name/uw/uwufetch/package.nix

   1 { lib, stdenv, fetchFromGitHub, makeWrapper, viu }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "uwufetch";
   5   version = "2.1";
   6
   7   src = fetchFromGitHub {
   8     owner = "TheDarkBug";
   9     repo = pname;
  10     rev = version;
  11     hash = "sha256-cA8sajh+puswyKikr0Jp9ei+EpVkH+vhEp+pTerkUqA=";
  12   };
  13
  14   postPatch = ''
  15     substituteInPlace uwufetch.c \
  16       --replace "/usr/lib/uwufetch" "$out/lib/uwufetch" \
  17       --replace "/usr/local/lib/uwufetch" "$out/lib/uwufetch" \
  18       --replace "/etc/uwufetch/config" "$out/etc/uwufetch/config"
  19     # fix command_path for package manager (nix-store)
  20     substituteInPlace fetch.c \
  21       --replace "/usr/bin" "/run/current-system/sw/bin"
  22   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
  23     substituteInPlace Makefile \
  24       --replace "local/bin" "bin" \
  25       --replace "local/lib" "lib" \
  26       --replace "local/include" "include" \
  27       --replace "local/share" "share"
  28   '';
  29
  30   nativeBuildInputs = [ makeWrapper ];
  31
  32   makeFlags = [
  33     "UWUFETCH_VERSION=${version}"
  34   ];
  35
  36   installFlags = [
  37     "DESTDIR=${placeholder "out"}"
  38     "ETC_DIR=${placeholder "out"}/etc"
  39   ];
  40
  41   postFixup = ''
  42     wrapProgram $out/bin/uwufetch \
  43       --prefix PATH ":" ${lib.makeBinPath [ viu ]}
  44   '';
  45
  46   meta = with lib; {
  47     description = "Meme system info tool for Linux";
  48     homepage = "https://github.com/TheDarkBug/uwufetch";
  49     license = licenses.gpl3Plus;
  50     platforms = platforms.unix;
  51     maintainers = with maintainers; [ bbjubjub ];
  52     mainProgram = "uwufetch";
  53   };
  54 }