pkgs/by-name/va/vale-ls/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   makeWrapper,
   6   rustPlatform,
   7   pkg-config,
   8   openssl,
   9   darwin,
  10   vale,
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "vale-ls";
  15   version = "0.3.8";
  16
  17   src = fetchFromGitHub {
  18     owner = "errata-ai";
  19     repo = "vale-ls";
  20     tag = "v${version}";
  21     hash = "sha256-+2peLqj3/ny0hDwJVKEp2XS68VO50IvpCB2fvZoEdJo=";
  22   };
  23
  24   nativeBuildInputs = [
  25     rustPlatform.bindgenHook
  26     pkg-config
  27     makeWrapper
  28   ];
  29
  30   buildInputs =
  31     [
  32       openssl
  33     ]
  34     ++ lib.optionals stdenv.hostPlatform.isDarwin (
  35       with darwin.apple_sdk.frameworks;
  36       [
  37         SystemConfiguration
  38       ]
  39     );
  40
  41   checkFlags =
  42     [
  43       # The following tests are reaching to the network.
  44       "--skip=vale::tests"
  45     ]
  46     ++ lib.optionals (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64) [
  47       # This test does not account for the existence of aarch64-linux machines,
  48       # despite upstream shipping artifacts for that architecture
  49       "--skip=utils::tests::arch"
  50     ];
  51
  52   env.OPENSSL_NO_VENDOR = true;
  53
  54   cargoHash = "sha256-YurMB54jeMQIAOgDQhXEYrkYUYrSl02M9JG5Wtp6Eb8=";
  55
  56   postInstall = ''
  57     wrapProgram $out/bin/vale-ls \
  58       --prefix PATH : ${lib.makeBinPath [ vale ]}
  59   '';
  60
  61   meta = with lib; {
  62     description = "LSP implementation for the Vale command-line tool";
  63     homepage = "https://github.com/errata-ai/vale-ls";
  64     license = licenses.mit;
  65     mainProgram = "vale-ls";
  66     maintainers = with maintainers; [
  67       foo-dogsquared
  68       jansol
  69     ];
  70   };
  71 }