pkgs/by-name/ve/veryl/package.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   pkg-config,
   6   installShellFiles,
   7   dbus,
   8   stdenv,
   9   darwin,
  10 }:
  11
  12 rustPlatform.buildRustPackage rec {
  13   pname = "veryl";
  14   version = "0.13.2";
  15
  16   src = fetchFromGitHub {
  17     owner = "veryl-lang";
  18     repo = "veryl";
  19     rev = "v${version}";
  20     hash = "sha256-LSQ3ZM7BWXiwBqlw6usImpt+w+wC2EvkoAMblTb0pvg=";
  21     fetchSubmodules = true;
  22   };
  23
  24   cargoHash = "sha256-w7mB0cAN5aRO1pw21BDIFUtnYUJUoYjW+7nXFCBfYgM=";
  25
  26   nativeBuildInputs = [
  27     pkg-config
  28     installShellFiles
  29   ];
  30
  31   buildInputs =
  32     [
  33       dbus
  34     ]
  35     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  36       darwin.apple_sdk.frameworks.CoreFoundation
  37       darwin.apple_sdk.frameworks.CoreServices
  38       darwin.apple_sdk.frameworks.Security
  39       darwin.apple_sdk.frameworks.SystemConfiguration
  40     ];
  41
  42   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  43     installShellCompletion --cmd veryl \
  44       --bash <($out/bin/veryl metadata --completion bash) \
  45       --fish <($out/bin/veryl metadata --completion fish) \
  46       --zsh <($out/bin/veryl metadata --completion zsh)
  47   '';
  48
  49   checkFlags = [
  50     # takes over an hour
  51     "--skip=tests::progress"
  52     # tempfile::tempdir().unwrap() -> "No such file or directory"
  53     "--skip=tests::bump_version"
  54     "--skip=tests::bump_version_with_commit"
  55     "--skip=tests::check"
  56     "--skip=tests::load"
  57     "--skip=tests::lockfile"
  58     "--skip=tests::publish"
  59     "--skip=tests::publish_with_commit"
  60     # "Permission Denied", while making its cache dir?
  61     "--skip=analyzer::test_25_dependency"
  62     "--skip=analyzer::test_68_std"
  63     "--skip=emitter::test_25_dependency"
  64     "--skip=emitter::test_68_std"
  65   ];
  66
  67   meta = {
  68     description = "Modern Hardware Description Language";
  69     homepage = "https://veryl-lang.org/";
  70     changelog = "https://github.com/veryl-lang/veryl/blob/${src.rev}/CHANGELOG.md";
  71     license = with lib.licenses; [
  72       mit
  73       asl20
  74     ];
  75     maintainers = with lib.maintainers; [ pbsds ];
  76     mainProgram = "veryl";
  77   };
  78 }