pkgs/by-name/vi/video-trimmer/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitLab,
   5   rustPlatform,
   6   cargo,
   7   pkg-config,
   8   meson,
   9   rustc,
  10   wrapGAppsHook4,
  11   desktop-file-utils,
  12   blueprint-compiler,
  13   ninja,
  14   gtk4,
  15   libadwaita,
  16   gst_all_1,
  17   ffmpeg-headless,
  18 }:
  19
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "video-trimmer";
  22   version = "0.9.0";
  23
  24   src = fetchFromGitLab {
  25     domain = "gitlab.gnome.org";
  26     owner = "YaLTeR";
  27     repo = "video-trimmer";
  28     rev = "refs/tags/v${finalAttrs.version}";
  29     hash = "sha256-4B3NNGww+UjI/VbsKL62vWlKye7NYXYPzlJ4TfywJDw=";
  30   };
  31
  32   cargoDeps = rustPlatform.fetchCargoTarball {
  33     inherit (finalAttrs) pname version src;
  34     hash = "sha256-vtV5TrF81TK4PUwzOF/CuDsKH1vTLO+4PFufyIOp2zk=";
  35   };
  36
  37   nativeBuildInputs = [
  38     pkg-config
  39     meson
  40     wrapGAppsHook4
  41     desktop-file-utils
  42     blueprint-compiler
  43     ninja
  44     # Present here in addition to buildInputs, because meson runs
  45     # `gtk4-update-icon-cache` during installPhase, thanks to:
  46     # https://gitlab.gnome.org/YaLTeR/video-trimmer/-/merge_requests/12
  47     gtk4
  48     rustPlatform.cargoSetupHook
  49     cargo
  50     rustc
  51   ];
  52
  53   buildInputs = [
  54     gtk4
  55     libadwaita
  56     gst_all_1.gstreamer
  57     gst_all_1.gst-plugins-base
  58     gst_all_1.gst-plugins-good # for scaletempo and webm
  59     gst_all_1.gst-plugins-bad
  60   ];
  61
  62   doCheck = true;
  63
  64   strictDeps = true;
  65
  66   preFixup = ''
  67     gappsWrapperArgs+=(
  68       --prefix PATH : "${lib.makeBinPath [ ffmpeg-headless ]}"
  69     )
  70   '';
  71
  72   meta = {
  73     homepage = "https://gitlab.gnome.org/YaLTeR/video-trimmer";
  74     description = "Trim videos quickly";
  75     maintainers =
  76       with lib.maintainers;
  77       [
  78         doronbehar
  79       ]
  80       ++ lib.teams.gnome-circle.members;
  81     license = lib.licenses.gpl3Plus;
  82     platforms = lib.platforms.linux;
  83     mainProgram = "video-trimmer";
  84   };
  85 })