pkgs/by-name/vi/viewnior/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   fetchpatch,
   6   meson,
   7   ninja,
   8   pkg-config,
   9   desktop-file-utils,
  10   gtk3,
  11   libpng,
  12   exiv2,
  13   lcms,
  14   intltool,
  15   gettext,
  16   shared-mime-info,
  17   glib,
  18   gdk-pixbuf,
  19   perl,
  20   wrapGAppsHook3,
  21   webp-pixbuf-loader,
  22   gnome,
  23   librsvg,
  24 }:
  25
  26 stdenv.mkDerivation rec {
  27   pname = "viewnior-gtk3";
  28   version = "1.8-unstable-2023-11-23";
  29
  30   src = fetchFromGitHub {
  31     #owner = "hellosiyan";
  32     #repo = "Viewnior";
  33     owner = "Artturin";
  34     repo = "Viewnior";
  35     # https://github.com/hellosiyan/Viewnior/pull/142
  36     rev = "23ce6e5630b24509d8009f17a833ad9e59b85fab";
  37     hash = "sha256-+/f0+og1Dd7eJK7P83+q4lf4SjzW2g6qNk8ZTxNAuDA=";
  38   };
  39
  40   nativeBuildInputs = [
  41     meson
  42     ninja
  43     pkg-config
  44     desktop-file-utils
  45     intltool
  46     gettext
  47     wrapGAppsHook3
  48   ];
  49
  50   buildInputs = [
  51     gtk3
  52     libpng
  53     exiv2
  54     lcms
  55     shared-mime-info
  56     glib
  57     gdk-pixbuf
  58     perl
  59   ];
  60
  61   postInstall = ''
  62     export GDK_PIXBUF_MODULE_FILE="${
  63       gnome._gdkPixbufCacheBuilder_DO_NOT_USE {
  64         extraLoaders = [
  65           webp-pixbuf-loader
  66           librsvg
  67         ];
  68       }
  69     }"
  70
  71     # gtk3 viewnior can be launched in wayland mode and does so by default
  72     # but moving around in a zoomed in image doesn't work
  73     gappsWrapperArgs+=(
  74       --set-default GDK_BACKEND x11
  75     )
  76   '';
  77
  78   meta = with lib; {
  79     description = "Fast and simple image viewer";
  80     longDescription = ''
  81       Viewnior is insipred by big projects like Eye of Gnome, because of it's
  82       usability and richness,and by GPicView, because of it's lightweight design and
  83       minimal interface. So here comes Viewnior - small and light, with no compromise
  84       with the quality of it's functions. The program is made with better integration
  85       in mind (follows Gnome HIG2).
  86     '';
  87     license = licenses.gpl3;
  88     homepage = "https://siyanpanayotov.com/project/viewnior/";
  89     maintainers = with maintainers; [
  90       smironov
  91       artturin
  92     ];
  93     platforms = platforms.gnu ++ platforms.linux;
  94     mainProgram = "viewnior";
  95   };
  96 }