pkgs/by-name/vi/vis/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   pkg-config,
   6   makeWrapper,
   7   copyDesktopItems,
   8   makeDesktopItem,
   9   ncurses,
  10   libtermkey,
  11   lua,
  12   tre,
  13   acl,
  14   libselinux,
  15 }:
  16
  17 let
  18   luaEnv = lua.withPackages (ps: [ ps.lpeg ]);
  19 in
  20 stdenv.mkDerivation rec {
  21   pname = "vis";
  22   version = "0.9";
  23
  24   src = fetchFromGitHub {
  25     rev = "v${version}";
  26     hash = "sha256-SYM3zlzhp3NdyOjtXc+pOiWY4/WA/Ax+qAWe18ggq3g=";
  27     repo = "vis";
  28     owner = "martanne";
  29   };
  30
  31   nativeBuildInputs = [
  32     pkg-config
  33     makeWrapper
  34     copyDesktopItems
  35   ];
  36
  37   buildInputs =
  38     [
  39       ncurses
  40       libtermkey
  41       luaEnv
  42       tre
  43     ]
  44     ++ lib.optionals stdenv.hostPlatform.isLinux [
  45       acl
  46       libselinux
  47     ];
  48
  49   postInstall = ''
  50     wrapProgram $out/bin/vis \
  51       --prefix LUA_CPATH ';' "${luaEnv}/lib/lua/${lua.luaversion}/?.so" \
  52       --prefix LUA_PATH ';' "${luaEnv}/share/lua/${lua.luaversion}/?.lua" \
  53       --prefix VIS_PATH : "\$HOME/.config:$out/share/vis"
  54   '';
  55
  56   desktopItems = [
  57     (makeDesktopItem {
  58       name = "vis";
  59       exec = "vis %U";
  60       type = "Application";
  61       icon = "accessories-text-editor";
  62       comment = meta.description;
  63       desktopName = "vis";
  64       genericName = "Text editor";
  65       categories = [
  66         "Application"
  67         "Development"
  68         "IDE"
  69       ];
  70       mimeTypes = [
  71         "text/plain"
  72         "application/octet-stream"
  73       ];
  74       startupNotify = false;
  75       terminal = true;
  76     })
  77   ];
  78
  79   meta = with lib; {
  80     description = "A vim like editor";
  81     homepage = "https://github.com/martanne/vis";
  82     license = licenses.isc;
  83     maintainers = with maintainers; [ ramkromberg ];
  84     platforms = platforms.unix;
  85   };
  86 }