pkgs/by-name/wc/wcurl/package.nix

   1 {
   2   stdenvNoCC,
   3   lib,
   4   coreutils,
   5   curl,
   6   fetchFromGitHub,
   7   gnused,
   8   installShellFiles,
   9   nix-update-script,
  10   makeBinaryWrapper,
  11   shunit2,
  12 }:
  13
  14 stdenvNoCC.mkDerivation (finalAttrs: {
  15   pname = "wcurl";
  16   version = "2024.12.08";
  17
  18   src = fetchFromGitHub {
  19     owner = "curl";
  20     repo = "wcurl";
  21     tag = "v${finalAttrs.version}";
  22     hash = "sha256-X6v03oYb/n9ALJXpx5HQojths7tv1rEftGUiQElv7aY=";
  23   };
  24
  25   strictDeps = true;
  26
  27   nativeBuildInputs = [
  28     installShellFiles
  29     makeBinaryWrapper
  30   ];
  31
  32   nativeCheckInputs = [ shunit2 ];
  33
  34   doCheck = true;
  35
  36   dontBuild = true;
  37
  38   postPatch = ''
  39     substituteInPlace wcurl \
  40       --replace-fail '"curl "' '"${curl}/bin/curl "'
  41   '';
  42
  43   checkPhase = ''
  44     runHook preCheck
  45
  46     tests/tests.sh
  47
  48     runHook postCheck
  49   '';
  50
  51   installPhase = ''
  52     runHook preInstall
  53
  54     install -D wcurl -t $out/bin
  55     installManPage wcurl.1
  56
  57     runHook postInstall
  58   '';
  59
  60   postFixup = ''
  61     wrapProgram $out/bin/wcurl \
  62       --inherit-argv0 \
  63       --prefix PATH : ${
  64         lib.makeBinPath [
  65           coreutils
  66           gnused
  67         ]
  68       }
  69   '';
  70
  71   passthru.updateScript = nix-update-script { };
  72
  73   meta = {
  74     homepage = "https://curl.se/wcurl";
  75     description = "Simple wrapper around curl to easily download files";
  76     mainProgram = "wcurl";
  77     license = lib.licenses.curl;
  78     maintainers = with lib.maintainers; [ deejayem ];
  79     platforms = lib.platforms.all;
  80   };
  81 })