pkgs/by-name/we/wealthfolio/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cargo-tauri,
   6   jq,
   7   libsoup_3,
   8   moreutils,
   9   nodejs,
  10   openssl,
  11   pkg-config,
  12   pnpm_9,
  13   rustPlatform,
  14   webkitgtk_4_1,
  15   wrapGAppsHook3,
  16   nix-update-script,
  17 }:
  18
  19 stdenv.mkDerivation (finalAttrs: {
  20   pname = "wealthfolio";
  21   version = "1.0.24";
  22
  23   src = fetchFromGitHub {
  24     owner = "afadil";
  25     repo = "wealthfolio";
  26     rev = "v${finalAttrs.version}";
  27     hash = "sha256-3EuZXP4CTUcc9tlIdfAQfvwK5RZXcBe/8YkyjL/ZOVg=";
  28   };
  29
  30   pnpmDeps = pnpm_9.fetchDeps {
  31     inherit (finalAttrs) src pname version;
  32     hash = "sha256-0mjflUoqVJzshgpmyk32+Br61nkvcSjmjN7nf+7ZXJE=";
  33   };
  34
  35   cargoRoot = "src-tauri";
  36   buildAndTestSubdir = finalAttrs.cargoRoot;
  37
  38   cargoDeps = rustPlatform.fetchCargoVendor {
  39     inherit (finalAttrs) pname version src;
  40     sourceRoot = "${finalAttrs.src.name}/${finalAttrs.cargoRoot}";
  41     hash = "sha256-QFIDiuoT4J4pv1VrU5twrcb9Eqo77bgsWQl1DURpghE=";
  42   };
  43
  44   nativeBuildInputs = [
  45     cargo-tauri.hook
  46     jq
  47     moreutils
  48     nodejs
  49     pkg-config
  50     pnpm_9.configHook
  51     rustPlatform.cargoSetupHook
  52     wrapGAppsHook3
  53   ];
  54
  55   buildInputs = [
  56     libsoup_3
  57     openssl
  58     webkitgtk_4_1
  59   ];
  60
  61   postPatch = ''
  62     jq \
  63       '.plugins.updater.endpoints = [ ]
  64       | .bundle.createUpdaterArtifacts = false' \
  65       src-tauri/tauri.conf.json \
  66       | sponge src-tauri/tauri.conf.json
  67   '';
  68
  69   passthru.updateScript = nix-update-script { };
  70
  71   meta = {
  72     description = "A Beautiful Private and Secure Desktop Investment Tracking Application";
  73     homepage = "https://wealthfolio.app/";
  74     license = lib.licenses.agpl3Only;
  75     mainProgram = "wealthfolio";
  76     maintainers = with lib.maintainers; [ kilianar ];
  77     platforms = lib.platforms.linux;
  78   };
  79 })