pkgs/by-name/xe/xed/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   python3Packages,
   6   llvmPackages,
   7 }:
   8
   9 let
  10   # mbuild is a custom build system used only to build xed
  11   mbuild = python3Packages.buildPythonPackage rec {
  12     pname = "mbuild";
  13     version = "2022.07.28";
  14
  15     src = fetchFromGitHub {
  16       owner = "intelxed";
  17       repo = "mbuild";
  18       rev = "v${version}";
  19       sha256 = "sha256-nVHHiaPbf+b+RntjUGjLLGS53e6c+seXIBx7AcTtiWU=";
  20     };
  21   };
  22
  23 in
  24 stdenv.mkDerivation rec {
  25   pname = "xed";
  26   version = "2024.02.22";
  27
  28   src = fetchFromGitHub {
  29     owner = "intelxed";
  30     repo = "xed";
  31     rev = "v${version}";
  32     sha256 = "sha256-LF4iJ1/Z3OifCiir/kU3ufZqtiRLeaJeAwuBqP2BCF4=";
  33   };
  34
  35   nativeBuildInputs = [
  36     mbuild
  37   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ llvmPackages.bintools ];
  38
  39   buildPhase = ''
  40     patchShebangs mfile.py
  41
  42     # this will build, test and install
  43     ./mfile.py test --prefix $out
  44     ./mfile.py examples
  45     mkdir -p $out/bin
  46     cp ./obj/wkit/examples/obj/xed $out/bin/
  47   '';
  48
  49   dontInstall = true; # already installed during buildPhase
  50
  51   meta = with lib; {
  52     broken = stdenv.hostPlatform.isAarch64;
  53     description = "Intel X86 Encoder Decoder (Intel XED)";
  54     homepage = "https://intelxed.github.io/";
  55     license = licenses.asl20;
  56     platforms = platforms.unix;
  57     maintainers = with maintainers; [ arturcygan ];
  58   };
  59 }