pkgs/by-name/xp/xprompt/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , writeText
   5 , fontconfig
   6 , libX11
   7 , libXft
   8 , libXinerama
   9 , conf ? null
  10 , nix-update-script
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "xprompt";
  15   version = "2.5.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "phillbush";
  19     repo = "xprompt";
  20     rev = "v${version}";
  21     sha256 = "sha256-pOayKngUlrMY3bFsP4Fi+VsOLKCUQU3tdkZ+0OY1SCo=";
  22   };
  23
  24   buildInputs = [
  25     fontconfig
  26     libX11
  27     libXft
  28     libXinerama
  29   ];
  30
  31   postPatch =
  32     let
  33       configFile =
  34         if lib.isDerivation conf || builtins.isPath conf
  35         then conf else writeText "config.h" conf;
  36     in
  37     lib.optionalString (conf != null) "cp ${configFile} config.h";
  38
  39   makeFlags = [ "CC:=$(CC)" "PREFIX=$(out)" ];
  40
  41   passthru.updateScript = nix-update-script { };
  42
  43   meta = with lib; {
  44     description = "Dmenu rip-off with contextual completion";
  45     longDescription = ''
  46       XPrompt is a prompt for X. XPrompt features a text input field where the
  47       user can type in a text subject to tab-completion.
  48     '';
  49     homepage = "https://github.com/phillbush/xprompt";
  50     license = licenses.mit;
  51     maintainers = with maintainers; [ azahi ];
  52     platforms = platforms.unix;
  53     mainProgram = "xprompt";
  54   };
  55 }