pkgs/by-name/yd/yder/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitHub,
   5   cmake,
   6   orcania,
   7   systemd,
   8   check,
   9   subunit,
  10   withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "yder";
  15   version = "1.4.20";
  16
  17   src = fetchFromGitHub {
  18     owner = "babelouest";
  19     repo = pname;
  20     rev = "v${version}";
  21     sha256 = "sha256-BaCF1r5mOYxj0zKc11uoKI9gVKuxWd8GaneGcV+qIFg=";
  22   };
  23
  24   patches = [
  25     # We set CMAKE_INSTALL_LIBDIR to the absolute path in $out, so
  26     # prefix and exec_prefix cannot be $out, too
  27     ./fix-pkgconfig.patch
  28   ];
  29
  30   nativeBuildInputs = [ cmake ];
  31
  32   buildInputs = [ orcania ] ++ lib.optional withSystemd systemd;
  33
  34   nativeCheckInputs = [
  35     check
  36     subunit
  37   ];
  38
  39   cmakeFlags = [
  40     "-DBUILD_YDER_TESTING=on"
  41   ] ++ lib.optional (!withSystemd) "-DWITH_JOURNALD=off";
  42
  43   doCheck = true;
  44
  45   meta = with lib; {
  46     description = "Logging library for C applications";
  47     homepage = "https://github.com/babelouest/yder";
  48     license = licenses.lgpl21;
  49     maintainers = with maintainers; [ johnazoidberg ];
  50     platforms = platforms.all;
  51   };
  52 }