pkgs/by-name/ze/zed-editor/package.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   clang,
   6   cmake,
   7   copyDesktopItems,
   8   curl,
   9   perl,
  10   pkg-config,
  11   protobuf,
  12   fontconfig,
  13   freetype,
  14   libgit2,
  15   openssl,
  16   sqlite,
  17   zlib,
  18   zstd,
  19   alsa-lib,
  20   libxkbcommon,
  21   wayland,
  22   libglvnd,
  23   xorg,
  24   stdenv,
  25   makeFontsConf,
  26   vulkan-loader,
  27   envsubst,
  28   gitUpdater,
  29   cargo-about,
  30   versionCheckHook,
  31   zed-editor,
  32   buildFHSEnv,
  33   cargo-bundle,
  34   git,
  35   apple-sdk_15,
  36   darwinMinVersionHook,
  37   makeWrapper,
  38   nodejs_22,
  39
  40   withGLES ? false,
  41 }:
  42
  43 assert withGLES -> stdenv.hostPlatform.isLinux;
  44
  45 let
  46   executableName = "zeditor";
  47   # Based on vscode.fhs
  48   # Zed allows for users to download and use extensions
  49   # which often include the usage of pre-built binaries.
  50   # See #309662
  51   #
  52   # buildFHSEnv allows for users to use the existing Zed
  53   # extension tooling without significant pain.
  54   fhs =
  55     {
  56       additionalPkgs ? pkgs: [ ],
  57     }:
  58     buildFHSEnv {
  59       # also determines the name of the wrapped command
  60       name = executableName;
  61
  62       # additional libraries which are commonly needed for extensions
  63       targetPkgs =
  64         pkgs:
  65         (with pkgs; [
  66           # ld-linux-x86-64-linux.so.2 and others
  67           glibc
  68         ])
  69         ++ additionalPkgs pkgs;
  70
  71       # symlink shared assets, including icons and desktop entries
  72       extraInstallCommands = ''
  73         ln -s "${zed-editor}/share" "$out/"
  74       '';
  75
  76       runScript = "${zed-editor}/bin/${executableName}";
  77
  78       passthru = {
  79         inherit executableName;
  80         inherit (zed-editor) pname version;
  81       };
  82
  83       meta = zed-editor.meta // {
  84         description = ''
  85           Wrapped variant of ${zed-editor.pname} which launches in a FHS compatible environment.
  86           Should allow for easy usage of extensions without nix-specific modifications.
  87         '';
  88       };
  89     };
  90 in
  91 rustPlatform.buildRustPackage rec {
  92   pname = "zed-editor";
  93   version = "0.163.3";
  94
  95   src = fetchFromGitHub {
  96     owner = "zed-industries";
  97     repo = "zed";
  98     rev = "refs/tags/v${version}";
  99     hash = "sha256-AkfMAGkxo4ZQVqR+8T9IgBMXvSyFd15jU5hCoAWDk0A=";
 100   };
 101
 102   patches =
 103     [
 104       # Zed uses cargo-install to install cargo-about during the script execution.
 105       # We provide cargo-about ourselves and can skip this step.
 106       # Until https://github.com/zed-industries/zed/issues/19971 is fixed,
 107       # we also skip any crate for which the license cannot be determined.
 108       ./0001-generate-licenses.patch
 109     ]
 110     ++ lib.optionals stdenv.hostPlatform.isDarwin [
 111       # The Swift variant of livekit currently used inside Zed requires
 112       # Swift 6, which is not available in nixpkgs yet:
 113       #   https://github.com/NixOS/nixpkgs/issues/343210
 114       # The Rust variant of livekit for Zed is still pending and there is no
 115       # schedule when it will be finished:
 116       #   https://github.com/zed-industries/zed/pull/13343
 117       ./0002-disable-livekit-darwin.patch
 118     ];
 119
 120   useFetchCargoVendor = true;
 121   cargoHash = "sha256-Ol7GPWACb8jGhki3rlLxNw3486+LOR2fyh7qVXWkGJ0=";
 122
 123   nativeBuildInputs =
 124     [
 125       clang
 126       cmake
 127       copyDesktopItems
 128       curl
 129       perl
 130       pkg-config
 131       protobuf
 132       rustPlatform.bindgenHook
 133       cargo-about
 134     ]
 135     ++ lib.optionals stdenv.hostPlatform.isLinux [ makeWrapper ]
 136     ++ lib.optionals stdenv.hostPlatform.isDarwin [ cargo-bundle ];
 137
 138   dontUseCmakeConfigure = true;
 139
 140   buildInputs =
 141     [
 142       curl
 143       fontconfig
 144       freetype
 145       libgit2
 146       openssl
 147       sqlite
 148       zlib
 149       zstd
 150     ]
 151     ++ lib.optionals stdenv.hostPlatform.isLinux [
 152       alsa-lib
 153       libxkbcommon
 154       wayland
 155       xorg.libxcb
 156     ]
 157     ++ lib.optionals stdenv.hostPlatform.isDarwin [
 158       apple-sdk_15
 159       # This will need to be increased to 12.3 once
 160       # https://github.com/zed-industries/zed/pull/13343
 161       # is merged and released, as ScreenCaptureKit is only available on 12.3 and up:
 162       # https://developer.apple.com/documentation/screencapturekit
 163       (darwinMinVersionHook "10.15")
 164     ];
 165
 166   cargoBuildFlags = [
 167     "--package=zed"
 168     "--package=cli"
 169   ];
 170
 171   # Required on darwin because we don't have access to the
 172   # proprietary Metal shader compiler.
 173   buildFeatures = lib.optionals stdenv.hostPlatform.isDarwin [ "gpui/runtime_shaders" ];
 174
 175   env = {
 176     ZSTD_SYS_USE_PKG_CONFIG = true;
 177     FONTCONFIG_FILE = makeFontsConf {
 178       fontDirectories = [
 179         "${src}/assets/fonts/plex-mono"
 180         "${src}/assets/fonts/plex-sans"
 181       ];
 182     };
 183     # Setting this environment variable allows to disable auto-updates
 184     # https://zed.dev/docs/development/linux#notes-for-packaging-zed
 185     ZED_UPDATE_EXPLANATION = "Zed has been installed using Nix. Auto-updates have thus been disabled.";
 186     # Used by `zed --version`
 187     RELEASE_VERSION = version;
 188   };
 189
 190   RUSTFLAGS = if withGLES then "--cfg gles" else "";
 191   gpu-lib = if withGLES then libglvnd else vulkan-loader;
 192
 193   preBuild = ''
 194     bash script/generate-licenses
 195   '';
 196
 197   postFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
 198     patchelf --add-rpath ${gpu-lib}/lib $out/libexec/*
 199     patchelf --add-rpath ${wayland}/lib $out/libexec/*
 200     wrapProgram $out/libexec/zed-editor --suffix PATH : ${lib.makeBinPath [ nodejs_22 ]}
 201   '';
 202
 203   preCheck = ''
 204     export HOME=$(mktemp -d);
 205   '';
 206
 207   checkFlags =
 208     [
 209       # Flaky: unreliably fails on certain hosts (including Hydra)
 210       "--skip=zed::tests::test_window_edit_state_restoring_enabled"
 211     ]
 212     ++ lib.optionals stdenv.hostPlatform.isLinux [
 213       # Fails on certain hosts (including Hydra) for unclear reason
 214       "--skip=test_open_paths_action"
 215     ];
 216
 217   installPhase =
 218     if stdenv.hostPlatform.isDarwin then
 219       ''
 220         runHook preInstall
 221
 222         # cargo-bundle expects the binary in target/release
 223         mv target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/zed target/release/zed
 224
 225         pushd crates/zed
 226
 227         # Note that this is GNU sed, while Zed's bundle-mac uses BSD sed
 228         sed -i "s/package.metadata.bundle-stable/package.metadata.bundle/" Cargo.toml
 229         export CARGO_BUNDLE_SKIP_BUILD=true
 230         app_path=$(cargo bundle --release | xargs)
 231
 232         # We're not using Zed's fork of cargo-bundle, so we must manually append their plist extensions
 233         # Remove closing tags from Info.plist (last two lines)
 234         head -n -2 $app_path/Contents/Info.plist > Info.plist
 235         # Append extensions
 236         cat resources/info/*.plist >> Info.plist
 237         # Add closing tags
 238         printf "</dict>\n</plist>\n" >> Info.plist
 239         mv Info.plist $app_path/Contents/Info.plist
 240
 241         popd
 242
 243         mkdir -p $out/Applications $out/bin
 244         # Zed expects git next to its own binary
 245         ln -s ${git}/bin/git $app_path/Contents/MacOS/git
 246         mv target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/cli $app_path/Contents/MacOS/cli
 247         mv $app_path $out/Applications/
 248
 249         # Physical location of the CLI must be inside the app bundle as this is used
 250         # to determine which app to start
 251         ln -s $out/Applications/Zed.app/Contents/MacOS/cli $out/bin/zeditor
 252
 253         runHook postInstall
 254       ''
 255     else
 256       ''
 257         runHook preInstall
 258
 259         mkdir -p $out/bin $out/libexec
 260         cp target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/zed $out/libexec/zed-editor
 261         cp target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/cli $out/bin/zeditor
 262
 263         install -D ${src}/crates/zed/resources/app-icon@2x.png $out/share/icons/hicolor/1024x1024@2x/apps/zed.png
 264         install -D ${src}/crates/zed/resources/app-icon.png $out/share/icons/hicolor/512x512/apps/zed.png
 265
 266         # extracted from https://github.com/zed-industries/zed/blob/v0.141.2/script/bundle-linux (envsubst)
 267         # and https://github.com/zed-industries/zed/blob/v0.141.2/script/install.sh (final desktop file name)
 268         (
 269           export DO_STARTUP_NOTIFY="true"
 270           export APP_CLI="zeditor"
 271           export APP_ICON="zed"
 272           export APP_NAME="Zed"
 273           export APP_ARGS="%U"
 274           mkdir -p "$out/share/applications"
 275           ${lib.getExe envsubst} < "crates/zed/resources/zed.desktop.in" > "$out/share/applications/dev.zed.Zed.desktop"
 276         )
 277
 278         runHook postInstall
 279       '';
 280
 281   nativeInstallCheckInputs = [
 282     versionCheckHook
 283   ];
 284   versionCheckProgram = "${placeholder "out"}/bin/zeditor";
 285   versionCheckProgramArg = [ "--version" ];
 286   doInstallCheck = true;
 287
 288   passthru = {
 289     updateScript = gitUpdater {
 290       rev-prefix = "v";
 291       ignoredVersions = "pre";
 292     };
 293     fhs = fhs { };
 294     fhsWithPackages = f: fhs { additionalPkgs = f; };
 295   };
 296
 297   meta = {
 298     description = "High-performance, multiplayer code editor from the creators of Atom and Tree-sitter";
 299     homepage = "https://zed.dev";
 300     changelog = "https://github.com/zed-industries/zed/releases/tag/v${version}";
 301     license = lib.licenses.gpl3Only;
 302     maintainers = with lib.maintainers; [
 303       GaetanLepage
 304       niklaskorz
 305     ];
 306     mainProgram = "zeditor";
 307     platforms = lib.platforms.linux ++ lib.platforms.darwin;
 308   };
 309 }