pkgs/by-name/zo/zola/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , rustPlatform
   5 , pkg-config
   6 , oniguruma
   7 , darwin
   8 , installShellFiles
   9 , zola
  10 , testers
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "zola";
  15   version = "0.19.2";
  16
  17   src = fetchFromGitHub {
  18     owner = "getzola";
  19     repo = "zola";
  20     rev = "v${version}";
  21     hash = "sha256-BjHAHj3EGE1L+EQdniS4OGOViOmcRDR5RhgmYK2zmVY=";
  22   };
  23
  24   cargoHash = "sha256-ZbSdPi90Nl15YYN1tx9iNsdAjh6x02XKGG73IlOKdXo=";
  25
  26   nativeBuildInputs = [
  27     pkg-config
  28     installShellFiles
  29   ];
  30
  31   buildInputs = [
  32     oniguruma
  33   ] ++ lib.optionals stdenv.hostPlatform.isDarwin (with darwin.apple_sdk.frameworks; [
  34     CoreServices SystemConfiguration
  35   ]);
  36
  37   RUSTONIG_SYSTEM_LIBONIG = true;
  38
  39   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  40     installShellCompletion --cmd zola \
  41       --bash <($out/bin/zola completion bash) \
  42       --fish <($out/bin/zola completion fish) \
  43       --zsh <($out/bin/zola completion zsh)
  44   '';
  45
  46   passthru.tests.version = testers.testVersion { package = zola; };
  47
  48   meta = with lib; {
  49     description = "Fast static site generator with everything built-in";
  50     mainProgram = "zola";
  51     homepage = "https://www.getzola.org/";
  52     changelog = "https://github.com/getzola/zola/raw/v${version}/CHANGELOG.md";
  53     license = licenses.mit;
  54     maintainers = with maintainers; [ dandellion dywedir _0x4A6F ];
  55   };
  56 }