pkgs/data/themes/layan-kde/default.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitHub,
   5   kdeclarative,
   6   plasma-framework,
   7   plasma-workspace,
   8   gitUpdater,
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12   pname = "layan-kde";
  13   version = "unstable-2023-09-30";
  14
  15   src = fetchFromGitHub {
  16     owner = "vinceliuice";
  17     repo = pname;
  18     rev = "7ab7cd7461dae8d8d6228d3919efbceea5f4272c";
  19     hash = "sha256-Wh8tZcQEdTTlgtBf4ovapojHcpPBZDDkWOclmxZv9zA=";
  20   };
  21
  22   # Propagate sddm theme dependencies to user env otherwise sddm does
  23   # not find them. Putting them in buildInputs is not enough.
  24   propagatedUserEnvPkgs = [
  25     kdeclarative.bin
  26     plasma-framework
  27     plasma-workspace
  28   ];
  29
  30   postPatch = ''
  31     patchShebangs install.sh
  32
  33     substituteInPlace install.sh \
  34       --replace '$HOME/.local' $out \
  35       --replace '$HOME/.config' $out/share
  36
  37     substituteInPlace sddm/*/Main.qml \
  38       --replace /usr $out
  39   '';
  40
  41   installPhase = ''
  42     runHook preInstall
  43
  44     name= ./install.sh --dest $out/share/themes
  45
  46     mkdir -p $out/share/sddm/themes
  47     cp -a sddm/Layan* $out/share/sddm/themes/
  48
  49     runHook postInstall
  50   '';
  51
  52   passthru.updateScript = gitUpdater { };
  53
  54   meta = with lib; {
  55     description = "Flat Design theme for KDE Plasma desktop";
  56     homepage = "https://github.com/vinceliuice/Layan-kde";
  57     license = licenses.gpl3Only;
  58     platforms = platforms.all;
  59     maintainers = [ maintainers.romildo ];
  60   };
  61 }