pkgs/desktops/mate/mate-tweak/default.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   python3Packages,
   5   intltool,
   6   mate,
   7   libnotify,
   8   gtk3,
   9   gdk-pixbuf,
  10   gobject-introspection,
  11   wrapGAppsHook3,
  12   glib,
  13   gitUpdater,
  14 }:
  15
  16 python3Packages.buildPythonApplication rec {
  17   pname = "mate-tweak";
  18   version = "22.10.0";
  19
  20   src = fetchFromGitHub {
  21     owner = "ubuntu-mate";
  22     repo = pname;
  23     rev = version;
  24     sha256 = "emeNgCzMhHMeLOyUkXe+8OzQMEWuwNdD4xkGXIFgbh4=";
  25   };
  26
  27   nativeBuildInputs = [
  28     wrapGAppsHook3
  29     intltool
  30     python3Packages.distutils-extra
  31     gobject-introspection
  32   ];
  33
  34   buildInputs = [
  35     gtk3
  36     gdk-pixbuf
  37     libnotify
  38     glib
  39     mate.mate-applets
  40     mate.mate-panel
  41     mate.marco
  42     mate.libmatekbd
  43     mate.mate-session-manager
  44   ];
  45
  46   propagatedBuildInputs = with python3Packages; [
  47     distro
  48     pygobject3
  49     psutil
  50     setproctitle
  51   ];
  52
  53   strictDeps = false;
  54
  55   dontWrapGApps = true;
  56
  57   postPatch = ''
  58     # mate-tweak hardcodes absolute paths everywhere. Nuke from orbit.
  59     find . -type f -exec sed -i \
  60       -e s,/usr/lib/mate-tweak,$out/lib/mate-tweak,g \
  61       {} +
  62
  63     sed -i 's,{prefix}/,,g' setup.py
  64   '';
  65
  66   # Arguments to be passed to `makeWrapper`, only used by buildPython*
  67   preFixup = ''
  68     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  69   '';
  70
  71   postFixup = ''
  72     for i in bin/.mate-tweak-wrapped lib/mate-tweak/mate-tweak-helper; do
  73       sed -i "s,usr,run/current-system/sw,g" $out/$i
  74     done
  75   '';
  76
  77   passthru.updateScript = gitUpdater { };
  78
  79   meta = with lib; {
  80     description = "Tweak tool for the MATE Desktop";
  81     homepage = "https://github.com/ubuntu-mate/mate-tweak";
  82     changelog = "https://github.com/ubuntu-mate/mate-tweak/releases/tag/${version}";
  83     license = [ licenses.gpl2Plus ];
  84     platforms = platforms.linux;
  85     maintainers = teams.mate.members;
  86   };
  87 }