pkgs/development/coq-modules/heq/default.nix

   1 {
   2   lib,
   3   fetchzip,
   4   mkCoqDerivation,
   5   coq,
   6   version ? null,
   7 }:
   8
   9 let
  10   fetcher =
  11     {
  12       rev,
  13       repo,
  14       owner,
  15       sha256,
  16       domain,
  17       ...
  18     }:
  19     fetchzip {
  20       url = "https://${domain}/${owner}/${repo}/download/${repo}-${rev}.zip";
  21       inherit sha256;
  22     };
  23 in
  24 mkCoqDerivation {
  25   pname = "heq";
  26   repo = "Heq";
  27   owner = "gil.hur";
  28   domain = "sf.snu.ac.kr";
  29   inherit version fetcher;
  30   defaultVersion = if lib.versions.isLt "8.8" coq.coq-version then "0.92" else null;
  31   release."0.92".sha256 = "0cf8y6728n81wwlbpq3vi7l2dbzi7759klypld4gpsjjp1y1fj74";
  32
  33   mlPlugin = true;
  34   preBuild = "cd src";
  35
  36   extraInstallFlags = [ "COQLIB=$(out)/lib/coq/${coq.coq-version}/" ];
  37
  38   meta = {
  39     homepage = "https://ropas.snu.ac.kr/~gil.hur/Heq/";
  40     description = "Heq : a Coq library for Heterogeneous Equality";
  41     maintainers = with lib.maintainers; [ jwiegley ];
  42   };
  43 }