pkgs/development/libraries/glibc/multi.nix

   1 {
   2   lib,
   3   runCommand,
   4   glibc,
   5   glibc32,
   6 }:
   7
   8 let
   9   nameVersion = builtins.parseDrvName glibc.name;
  10   glibc64 = glibc;
  11 in
  12 runCommand "${nameVersion.name}-multi-${nameVersion.version}"
  13   # out as the first output is an exception exclusive to glibc
  14   {
  15     outputs = [
  16       "out"
  17       "bin"
  18       "dev"
  19     ]; # TODO: no static version here (yet)
  20     passthru = {
  21       libgcc = lib.lists.filter (x: x != null) [
  22         (glibc64.libgcc or null)
  23         (glibc32.libgcc or null)
  24       ];
  25     };
  26   }
  27   ''
  28     mkdir -p "$out/lib"
  29     ln -s '${glibc64.out}'/lib/* "$out/lib"
  30     ln -s '${glibc32.out}/lib' "$out/lib/32"
  31     ln -s lib "$out/lib64"
  32
  33     # fixing ldd RLTDLIST
  34     mkdir -p "$bin/bin"
  35     cp -s '${glibc64.bin}'/bin/* "$bin/bin/"
  36     rm "$bin/bin/ldd"
  37     sed -e "s|^RTLDLIST=.*$|RTLDLIST=\"$out/lib/ld-linux-x86-64.so.2 $out/lib/32/ld-linux.so.2\"|g" \
  38         '${glibc64.bin}/bin/ldd' > "$bin/bin/ldd"
  39     chmod +x "$bin/bin/ldd"
  40
  41     mkdir "$dev"
  42     cp -rs '${glibc32.dev}'/include "$dev/"
  43     chmod +w -R "$dev"
  44     cp -rsf '${glibc64.dev}'/include "$dev/"
  45   ''