pkgs/development/libraries/hyphen/dictionaries.nix

   1 /* hyphen dictionaries */
   2
   3 { hyphen, stdenv, lib, fetchgit, fetchurl }:
   4
   5
   6 let
   7   libreofficeRepository = "https://anongit.freedesktop.org/git/libreoffice/dictionaries.git";
   8   libreofficeCommit = "9e27d044d98e65f89af8c86df722a77be827bdc8";
   9   libreofficeSubdir = "de";
  10
  11   mkDictFromLibreofficeGit =
  12     { subdir, shortName, shortDescription, dictFileName, readmeFileName }:
  13     stdenv.mkDerivation rec {
  14       version = "24.8";
  15       pname = "hyphen-dict-${shortName}-libreoffice";
  16       src = fetchgit {
  17         url = "https://anongit.freedesktop.org/git/libreoffice/dictionaries.git";
  18         rev = "a2bf59878dd76685803ec260e15d875746ad6e25";
  19         hash = "sha256-3CvjgNjsrm4obATK6LmtYob8i2ngTbwP6FB4HlJMPCE=";
  20       };
  21       meta = with lib; {
  22         description = "Hyphen dictionary for ${shortDescription} from LibreOffice";
  23         homepage = "https://wiki.documentfoundation.org/Development/Dictionaries";
  24         license = with licenses; [ mpl20 ];
  25         maintainers = with maintainers; [ theCapypara ];
  26         platforms = platforms.all;
  27       };
  28       dontBuild = true;
  29       installPhase = ''
  30         runHook preInstall
  31         cd $src/${subdir}
  32         install -dm755 "$out/share/hyphen"
  33         install -m644 "hyph_${dictFileName}.dic" "$out/share/hyphen"
  34         # docs
  35         install -dm755 "$out/share/doc/"
  36         install -m644 "README_hyph_${readmeFileName}.txt" "$out/share/doc/${pname}.txt"
  37         runHook postInstall
  38       '';
  39     };
  40
  41 in
  42 rec {
  43
  44   /* ENGLISH */
  45
  46   en_US = en-us;
  47   en-us = stdenv.mkDerivation rec {
  48     nativeBuildInputs = hyphen.nativeBuildInputs;
  49     version = hyphen.version;
  50     pname = "hyphen-dict-en-us";
  51     src =  hyphen.src;
  52     meta = {
  53       inherit (hyphen.meta) homepage platforms license maintainers;
  54       description = "Hyphen dictionary for English (United States)";
  55     };
  56     installPhase = ''
  57       runHook preInstall
  58       make install-hyphDATA
  59       runHook postInstall
  60     '';
  61   };
  62
  63   /* GERMAN */
  64
  65   de_DE = de-de;
  66   de-de = mkDictFromLibreofficeGit {
  67     subdir = "de";
  68     shortName = "de-de";
  69     shortDescription = "German (Germany)";
  70     dictFileName = "de_DE";
  71     readmeFileName = "de";
  72   };
  73
  74   de_AT = de-at;
  75   de-at = mkDictFromLibreofficeGit {
  76     subdir = "de";
  77     shortName = "de-at";
  78     shortDescription = "German (Austria)";
  79     dictFileName = "de_AT";
  80     readmeFileName = "de";
  81   };
  82
  83   de_CH = de-ch;
  84   de-ch = mkDictFromLibreofficeGit {
  85     subdir = "de";
  86     shortName = "de-ch";
  87     shortDescription = "German (Switzerland)";
  88     dictFileName = "de_CH";
  89     readmeFileName = "de";
  90   };
  91 }