pkgs/development/libraries/kde-frameworks/kinit/default.nix

   1 {
   2   mkDerivation,
   3   lib,
   4   stdenv,
   5   writeScript,
   6   extra-cmake-modules,
   7   kdoctools,
   8   kconfig,
   9   kcrash,
  10   ki18n,
  11   kio,
  12   kparts,
  13   kservice,
  14   kwindowsystem,
  15   plasma-framework,
  16 }:
  17
  18 let
  19   inherit (lib) getLib;
  20 in
  21
  22 mkDerivation {
  23   pname = "kinit";
  24   outputs = [
  25     "out"
  26     "dev"
  27   ];
  28   nativeBuildInputs = [
  29     extra-cmake-modules
  30     kdoctools
  31   ];
  32   buildInputs = [
  33     kconfig
  34     kcrash
  35     ki18n
  36     kio
  37     kservice
  38     kwindowsystem
  39   ];
  40   patches = [
  41     ./0002-start_kdeinit-path.patch
  42     ./0003-kdeinit-extra-libs.patch
  43     ./0004-start_kdeinit-environ-hard-limit.patch
  44   ];
  45   CXXFLAGS =
  46     [
  47       ''-DNIXPKGS_KF5_KIOCORE=\"${getLib kio}/lib/libKF5KIOCore.so.5\"''
  48       ''-DNIXPKGS_KF5_PARTS=\"${getLib kparts}/lib/libKF5Parts.so.5\"''
  49     ]
  50     ++ lib.optionals stdenv.hostPlatform.isLinux [
  51       ''-DNIXPKGS_KF5_PLASMA=\"${getLib plasma-framework}/lib/libKF5Plasma.so.5\"''
  52     ];
  53   setupHook = writeScript "setup-hook.sh" ''
  54     kinitFixupOutputHook() {
  55         if [ $prefix != ''${!outputBin} ] && [ -d $prefix/lib ]; then
  56             mkdir -p ''${!outputBin}/lib
  57             find $prefix/lib -maxdepth 1 -name 'libkdeinit5_*.so' -exec ln -s \{\} ''${!outputBin}/lib \;
  58             rmdir --ignore-fail-on-non-empty ''${!outputBin}/lib
  59         fi
  60     }
  61
  62     fixupOutputHooks+=(kinitFixupOutputHook)
  63   '';
  64 }