pkgs/development/libraries/libbluray/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   pkg-config,
   6   fontconfig,
   7   autoreconfHook,
   8   DiskArbitration,
   9   withJava ? false,
  10   jdk17,
  11   ant,
  12   stripJavaArchivesHook,
  13   withAACS ? false,
  14   libaacs,
  15   withBDplus ? false,
  16   libbdplus,
  17   withMetadata ? true,
  18   libxml2,
  19   withFonts ? true,
  20   freetype,
  21 }:
  22
  23 # Info on how to use:
  24 # https://wiki.archlinux.org/index.php/BluRay
  25
  26 stdenv.mkDerivation rec {
  27   pname = "libbluray";
  28   version = "1.3.4";
  29
  30   src = fetchurl {
  31     url = "https://get.videolan.org/libbluray/${version}/${pname}-${version}.tar.bz2";
  32     hash = "sha256-R4/9aKD13ejvbKmJt/A1taCiLFmRQuXNP/ewO76+Xys=";
  33   };
  34
  35   nativeBuildInputs =
  36     [
  37       pkg-config
  38       autoreconfHook
  39     ]
  40     ++ lib.optionals withJava [
  41       jdk17
  42       ant
  43       stripJavaArchivesHook
  44     ];
  45
  46   buildInputs =
  47     [ fontconfig ]
  48     ++ lib.optional withMetadata libxml2
  49     ++ lib.optional withFonts freetype
  50     ++ lib.optional stdenv.hostPlatform.isDarwin DiskArbitration;
  51
  52   propagatedBuildInputs = lib.optional withAACS libaacs;
  53
  54   env.JAVA_HOME = lib.optionalString withJava jdk17.home; # Fails at runtime without this
  55   env.NIX_LDFLAGS =
  56     lib.optionalString withAACS "-L${libaacs}/lib -laacs"
  57     + lib.optionalString withBDplus " -L${libbdplus}/lib -lbdplus";
  58
  59   configureFlags =
  60     lib.optional (!withJava) "--disable-bdjava-jar"
  61     ++ lib.optional (!withMetadata) "--without-libxml2"
  62     ++ lib.optional (!withFonts) "--without-freetype";
  63
  64   meta = with lib; {
  65     homepage = "http://www.videolan.org/developers/libbluray.html";
  66     description = "Library to access Blu-Ray disks for video playback";
  67     license = licenses.lgpl21;
  68     maintainers = with maintainers; [ abbradar ];
  69     platforms = platforms.unix;
  70   };
  71 }