pkgs/development/libraries/libgrss/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   fetchpatch,
   6   pkg-config,
   7   vala,
   8   gobject-introspection,
   9   gtk-doc,
  10   docbook_xsl,
  11   docbook_xml_dtd_412,
  12   glib,
  13   libxml2,
  14   libsoup_2_4,
  15   gnome,
  16   buildPackages,
  17   Foundation,
  18   AppKit,
  19 }:
  20
  21 stdenv.mkDerivation rec {
  22   pname = "libgrss";
  23   version = "0.7.0";
  24
  25   outputs = [
  26     "out"
  27     "dev"
  28     "devdoc"
  29   ];
  30
  31   src = fetchurl {
  32     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  33     sha256 = "1nalslgyglvhpva3px06fj6lv5zgfg0qmj0sbxyyl5d963vc02b7";
  34   };
  35
  36   patches = [
  37     (fetchpatch {
  38       name = "CVE-2016-20011.patch";
  39       # https://gitlab.gnome.org/GNOME/libgrss/-/merge_requests/7, not yet merged!
  40       url = "https://gitlab.gnome.org/GNOME/libgrss/-/commit/2c6ea642663e2a44efc8583fae7c54b7b98f72b3.patch";
  41       sha256 = "1ijvq2jl97vphcvrbrqxvszdmv6yyjfygdca9vyaijpafwyzzb18";
  42     })
  43   ];
  44
  45   nativeBuildInputs = [
  46     pkg-config
  47     vala
  48     gobject-introspection
  49     gtk-doc
  50     docbook_xsl
  51     docbook_xml_dtd_412
  52   ];
  53
  54   buildInputs =
  55     [
  56       glib
  57       libxml2
  58       libsoup_2_4
  59     ]
  60     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  61       Foundation
  62       AppKit
  63     ];
  64
  65   configureFlags =
  66     [
  67       "PKG_CONFIG=${buildPackages.pkg-config}/bin/${buildPackages.pkg-config.targetPrefix}pkg-config"
  68     ]
  69     ++ lib.optionals (stdenv.buildPlatform == stdenv.hostPlatform) [
  70       "--enable-gtk-doc"
  71     ];
  72
  73   doCheck = true;
  74
  75   passthru = {
  76     updateScript = gnome.updateScript {
  77       packageName = pname;
  78       versionPolicy = "none";
  79     };
  80   };
  81
  82   meta = with lib; {
  83     description = "Glib abstaction to handle feeds in RSS, Atom and other formats";
  84     homepage = "https://gitlab.gnome.org/GNOME/libgrss";
  85     license = licenses.lgpl3Plus;
  86     maintainers = teams.gnome.members;
  87     platforms = platforms.unix;
  88   };
  89 }