pkgs/development/libraries/mpich/default.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   perl,
   6   gfortran,
   7   automake,
   8   autoconf,
   9   openssh,
  10   hwloc,
  11   python3,
  12   darwin,
  13   # either libfabric or ucx work for ch4backend on linux. On darwin, neither of
  14   # these libraries currently build so this argument is ignored on Darwin.
  15   ch4backend,
  16   # Process managers to build (`--with-pm`),
  17   # cf. https://github.com/pmodels/mpich/blob/b80a6d7c24defe7cdf6c57c52430f8075a0a41d6/README.vin#L562-L586
  18   withPm ? [
  19     "hydra"
  20     "gforker"
  21   ],
  22   pmix,
  23   # PMIX support is likely incompatible with process managers (`--with-pm`)
  24   # https://github.com/NixOS/nixpkgs/pull/274804#discussion_r1432601476
  25   pmixSupport ? false,
  26 }:
  27
  28 let
  29   withPmStr = if withPm != [ ] then builtins.concatStringsSep ":" withPm else "no";
  30 in
  31
  32 assert (ch4backend.pname == "ucx" || ch4backend.pname == "libfabric");
  33
  34 stdenv.mkDerivation rec {
  35   pname = "mpich";
  36   version = "4.2.3";
  37
  38   src = fetchurl {
  39     url = "https://www.mpich.org/static/downloads/${version}/mpich-${version}.tar.gz";
  40     hash = "sha256-egGRgMUdFzitnF2NRSMU3mXoKO4kC8stH4DemmW+iKg=";
  41   };
  42
  43   patches = [
  44     # Disables ROMIO test which was enabled in
  45     # https://github.com/pmodels/mpich/commit/09686f45d77b7739f7aef4c2c6ef4c3060946595
  46     # The test searches for mpicc in $out/bin, which is not yet present in the checkPhase
  47     # Moreover it fails one test.
  48     ./disable-romio-tests.patch
  49   ];
  50
  51   outputs = [
  52     "out"
  53     "doc"
  54     "man"
  55   ];
  56
  57   configureFlags =
  58     [
  59       "--enable-shared"
  60       "--with-pm=${withPmStr}"
  61     ]
  62     ++ lib.optionals (lib.versionAtLeast gfortran.version "10") [
  63       "FFLAGS=-fallow-argument-mismatch" # https://github.com/pmodels/mpich/issues/4300
  64       "FCFLAGS=-fallow-argument-mismatch"
  65     ]
  66     ++ lib.optionals pmixSupport [
  67       "--with-pmix"
  68     ];
  69
  70   enableParallelBuilding = true;
  71
  72   nativeBuildInputs = [
  73     gfortran
  74     python3
  75     autoconf
  76     automake
  77   ];
  78   buildInputs =
  79     [
  80       perl
  81       openssh
  82       hwloc
  83     ]
  84     ++ lib.optional (!stdenv.hostPlatform.isDarwin) ch4backend
  85     ++ lib.optional pmixSupport pmix
  86     ++ lib.optional stdenv.hostPlatform.isDarwin darwin.apple_sdk.frameworks.Foundation;
  87
  88   # test_double_serializer.test fails on darwin
  89   doCheck = !stdenv.hostPlatform.isDarwin;
  90
  91   preFixup = ''
  92     # Ensure the default compilers are the ones mpich was built with
  93     sed -i 's:CC="gcc":CC=${stdenv.cc}/bin/gcc:' $out/bin/mpicc
  94     sed -i 's:CXX="g++":CXX=${stdenv.cc}/bin/g++:' $out/bin/mpicxx
  95     sed -i 's:FC="gfortran":FC=${gfortran}/bin/gfortran:' $out/bin/mpifort
  96   '';
  97
  98   meta = {
  99     # As far as we know, --with-pmix silently disables all of `--with-pm`
 100     broken = pmixSupport && withPm != [ ];
 101
 102     description = "Implementation of the Message Passing Interface (MPI) standard";
 103
 104     longDescription = ''
 105       MPICH2 is a free high-performance and portable implementation of
 106       the Message Passing Interface (MPI) standard, both version 1 and
 107       version 2.
 108     '';
 109     homepage = "http://www.mcs.anl.gov/mpi/mpich2/";
 110     license = {
 111       url = "http://git.mpich.org/mpich.git/blob/a385d6d0d55e83c3709ae851967ce613e892cd21:/COPYRIGHT";
 112       fullName = "MPICH license (permissive)";
 113     };
 114     maintainers = [ lib.maintainers.markuskowa ];
 115     platforms = lib.platforms.linux ++ lib.platforms.darwin;
 116   };
 117 }